![](/i/fill.gif) |
![](/i/fill.gif) |
|
![](/i/fill.gif) |
|
![](/i/fill.gif) |
| ![](/i/fill.gif) |
| ![](/i/fill.gif) |
|
![](/i/fill.gif) |
|
![](/i/fill.gif) |
| ![](/i/fill.gif) |
| ![](/i/fill.gif) |
|
![](/i/fill.gif) |
I think you're having to deal with environmental factors; which is to say,
it all depends on how the light source object is applied to the scene. The
background is paramount when transparency is involved. I changed some things
but basically everyone is right about using merge to remove inside surfaces
first and foremost. To get the glowing effect you must look through at least
the edges of a media object. If the object is directly between a background
and camera then the appearance is different than when not aligned.
Obviously, the main concern with this particular scene is how to go about
getting a brighter interior and at the same time dimmer edges. I reduced the
transmit for one thing, that always tends to overbrighten the container
object if filter is used in conjunction.
Anyway, check out:
global_settings {
radiosity {}
photons {
spacing .03
media 100,2
}
}
#declare NixieColor = color rgbft<1.00,0.5,0.00,1,.5>;
#declare NixieColorEmit = color rgb<1.00,0.5,0.00>;
#declare NixieColorScat = color rgb<1.00,0.5,0.00>/5;
#declare Number1 =
merge {
cylinder {<0,-0.95,0>,<0,0.95,0>,0.1}
sphere {<0,-0.95,0>,0.1}
sphere {<0, 0.95,0>,0.1}
pigment {NixieColor}
finish {ambient 0 diffuse 0}
interior {
media {
emission NixieColor//Emit
scattering { 4, NixieColorScat}
density {rgb 2}
intervals 1
samples 20
method 3
}
}
hollow
photons {target reflection on collect on}
}
#declare NixieNumber1 =
light_source {
0,
NixieColor
looks_like {Number1}
area_light .1*x,y,2,6 jitter
fade_distance 1
fade_power 2
photons {reflection on}
}
object{NixieNumber1 scale .25 translate <-1,-1,0>/3}
// things to see the light source and photons against
plane {z,1 pigment {rgb 1} hollow photons {target}}
box {-1,1 pigment {rgb 0} finish {reflection 1}
photons {target reflection on}
rotate <30,30,0>
// rotate 15*y // add this to see number object on box
translate <1.5,1,-.5>}
camera {
location <0, 0, -3>
look_at 0
angle 50
}
Post a reply to this message
|
![](/i/fill.gif) |
| ![](/i/fill.gif) |
| ![](/i/fill.gif) |
|
![](/i/fill.gif) |
|
![](/i/fill.gif) |
| ![](/i/fill.gif) |
| ![](/i/fill.gif) |
|
![](/i/fill.gif) |
> Well I thought about that but I also want the object
> to actually emit light too.
Emitting media works like ambient. It doesn't really emit light.
I was curious as to how it would look with pigments. I made an experiment:
//camera { location <-2,1,-3> look_at 0 }
//camera { orthographic location -3*z look_at 0 }
camera { location -3*z look_at 0 }
light_source { <-15,45,-60>,1 }
#declare Color1=<1, 1, .8 ,.9>;
#declare Color2=<1, 1, .5 ,.65>;
#declare Color3=<1.35, 1.35 ,1.35,0>;
#declare Cyl = cylinder { -1*y, 1*y, .15
pigment { cylindrical pigment_map {
[ 0 rgbt 1 ]
[ .15 rgbt Color1 ]
[ .39 rgbt Color2 ]
[ 1 rgbt Color3 ] }
scale <.135,1,1> }
finish { ambient 1 diffuse 0 }
}
#declare Sph = sphere { 0, .15
pigment { spherical pigment_map {
[ 0 rgbt 1 ]
[ .15 rgbt Color1 ]
[ .39 rgbt Color2 ]
[ 1 rgbt Color3 ] }
scale <.135,.13,1> }
finish { ambient 1 diffuse 0 }
}
#declare Number0 = merge {
#local cnt=0;
#local step=.01;
#while (cnt<1)
object { Cyl scale <1,.04,1>
translate .95*x rotate (cnt*360)*z }
#local cnt=cnt+step;
#end
no_shadow
bounded_by { box { <-1.3,1.3,.15>,<1.3,-1.3,-.15> }}
}
#declare Number1 = merge {
object { Cyl scale <1,.95,1> pigment { turbulence .12 }}
object { Sph translate -.95*y }
object { Sph translate .95*y }
no_shadow
}
object { Number0 translate -.5*x }
object { Number1 translate 1.2*x }
plane { z,10
pigment { wrinkles
pigment_map { [ 0 rgb .5 ] [ 1 rgb <1,.7,.6> ] }
scale 4 }
hollow
}
Post a reply to this message
|
![](/i/fill.gif) |
| ![](/i/fill.gif) |
| ![](/i/fill.gif) |
|
![](/i/fill.gif) |
|
![](/i/fill.gif) |
| ![](/i/fill.gif) |
| ![](/i/fill.gif) |
|
![](/i/fill.gif) |
Yes! That is what I'm trying to get to. It looks like an element from
an electric stove top. Great!
Thanks!
Patrick Dugan
"hughes b" <omn### [at] charter net> wrote in message
news:3d3393e3@news.povray.org...
> I think you're having to deal with environmental factors; which is to say,
> it all depends on how the light source object is applied to the scene. The
> background is paramount when transparency is involved. I changed some
things
> but basically everyone is right about using merge to remove inside
surfaces
> first and foremost. To get the glowing effect you must look through at
least
> the edges of a media object. If the object is directly between a
background
> and camera then the appearance is different than when not aligned.
> Obviously, the main concern with this particular scene is how to go about
> getting a brighter interior and at the same time dimmer edges. I reduced
the
> transmit for one thing, that always tends to overbrighten the container
> object if filter is used in conjunction.
> Anyway, check out:
>
> global_settings {
> radiosity {}
> photons {
> spacing .03
> media 100,2
> }
> }
>
> #declare NixieColor = color rgbft<1.00,0.5,0.00,1,.5>;
> #declare NixieColorEmit = color rgb<1.00,0.5,0.00>;
> #declare NixieColorScat = color rgb<1.00,0.5,0.00>/5;
>
> #declare Number1 =
> merge {
> cylinder {<0,-0.95,0>,<0,0.95,0>,0.1}
> sphere {<0,-0.95,0>,0.1}
> sphere {<0, 0.95,0>,0.1}
> pigment {NixieColor}
> finish {ambient 0 diffuse 0}
> interior {
> media {
> emission NixieColor//Emit
> scattering { 4, NixieColorScat}
> density {rgb 2}
> intervals 1
> samples 20
> method 3
> }
> }
> hollow
> photons {target reflection on collect on}
> }
>
> #declare NixieNumber1 =
> light_source {
> 0,
> NixieColor
> looks_like {Number1}
> area_light .1*x,y,2,6 jitter
> fade_distance 1
> fade_power 2
> photons {reflection on}
> }
>
> object{NixieNumber1 scale .25 translate <-1,-1,0>/3}
>
> // things to see the light source and photons against
> plane {z,1 pigment {rgb 1} hollow photons {target}}
> box {-1,1 pigment {rgb 0} finish {reflection 1}
> photons {target reflection on}
> rotate <30,30,0>
> // rotate 15*y // add this to see number object on box
> translate <1.5,1,-.5>}
>
> camera {
> location <0, 0, -3>
> look_at 0
> angle 50
> }
>
>
>
>
Post a reply to this message
|
![](/i/fill.gif) |
| ![](/i/fill.gif) |
| ![](/i/fill.gif) |
|
![](/i/fill.gif) |
|
![](/i/fill.gif) |
| ![](/i/fill.gif) |
|
![](/i/fill.gif) |