I had asked before if it were possible to have both components of a blob
contribute equally to the shape but have one component "dominate the
texture" contibution.  Bob H helped me see this wasn't "possible" with
straightforward coding.

The application was where I have a blob model of a person.  Where the
flesh-colored neck intersects the clothing-textured ribcage, I get an
unrealistic blurrily-pigmented  interface.

Here's a workaround, which may have applications for others:   just use a
pigment map!



light_source { <-5, 5, -20>,1.5 }

camera {
   location  -0.5*z
   look_at   0
}
  text {
    ttf "timrom.ttf" "CSG showing what I wanted" .1, 0
    pigment { red 1 }
    scale 0.12
    translate <-0.9,.55,1>  }

cylinder {-1*x,0,.05 pigment {rgb 0.8} translate <0, 0.4 1>}
sphere {0.1*x,.05 pigment {red 1} translate <-0.055, 0.4, 1>}
sphere {-0.95*x,0.05 pigment {rgb 0.8} translate <-0.055, 0.4, 1>}
cylinder {0,x*0.05,.05 pigment {red 1} translate <0, 0.4 1>}



text {
    ttf "timrom.ttf" "blob trick using texture map & Grad x" .1, 0
    pigment { red 1 }
    scale 0.12
    translate <-0.9,.1,1>  }
blob {
   threshold .6
   cylinder {-1*x,0,.125,1  pigment {
                gradient x
                pigment_map{
                [0.5 red 1]
                [0.5 rgb 0.8]}
                scale 4
                translate -0.02*x
                }
            translate <0, 0, 1>}
   sphere {0.125*x,0.1,1 pigment {red 1} translate <-0.055, -0,1>}
}


text {
    ttf "timrom.ttf" "blob showing undesired effect" .1, 0
    pigment { red 1 }
    scale 0.12
    translate <-0.9,-.25,1>  }

blob {
   threshold .6
   cylinder {-1*x,0,.125,1 pigment {rgb 0.8} translate <0, -0.4 1>}
   sphere {0.125*x,0.1,1 pigment {red 1} translate <-0.055, -0.4, 1>}
}

Post a reply to this message

Attachments:
Download 'bp05.JPG' (27 KB)

Preview of image 'bp05.JPG'

The old saying, where there's a will there's a way, comes to mind. Congrats
on coming up with a workaround. Trying it out here something is illogical
about what's happening, or I just haven't grasped the meaning of it yet.

I just tried this out to get a match head:

blob {
   threshold .6
   cylinder {-1*x,0,.125,1  pigment {
                gradient x
                pigment_map{
                [0.47 red 1]
                [0.53 rgb 0.8]}
                triangle_wave scale 2 //frequency -1
                translate .5*x
                }
            translate <0, 0, 1>}
   sphere {0.125*x,0.1,1 pigment {//red 1}
                gradient x
                pigment_map{
                [0.8 red 1]
                [0.9 rgb 0.8]}
                scallop_wave scale .25 //frequency -1
                translate -.2*x
                }
    translate <-0.055, -0,1>}
}

There's obviously some control with this, but so far it's not exactly simple
at all for me to figure what I'm doing.

bob h

Post a reply to this message