Hi,

I just started to create a Motorbike. But I have no (good) Idea to create a
texture for the glas of the headlight. Any tips?

Tilly
http://www.tabsnet.com/

Post a reply to this message

and now, the second part :-) the image.

 Tilly
 http://www.tabsnet.com/

Post a reply to this message

Attachments:
Download 'bike_and_car018.jpg' (58 KB)

Preview of image 'bike_and_car018.jpg'

"Tilly" <web### [at] tabsnetde> wrote in message
news:3b81461e$1@news.povray.org...
> Hi,
>
> I just started to create a Motorbike. But I have no (good) Idea to create
a
> texture for the glas of the headlight. Any tips?

Hmmm... synchronicity at work here I think, for i've recently been
considering such an attempt myself. My own thoughts on the headlamp would be
to use a height_field for the outer 'displacement' of the glass (I take it
that's what you mean by 'texture'?). A simple glass finish should suffice.

Looking really good by the way. Are you going to keep an extremely high
level of detail for engine/brake components etc?

I suggest a pearlescent paint job! That should cause you a few headaches ;-)

All the best,
Andy Cocker

Post a reply to this message

Hi Andy,

thank's for the tip and yes I'm going to keep high level of details for this
model.
Because, I'm drive a Motorbike in the real world...

Tilly,
http://www.tabsnet.com/

Post a reply to this message

Looks nice.
Here is a headlight from an old project of mine.

Jay Raney


//--------------------------------
background { rgb 1 }

light_source { <-200,100,-60> rgb 1 }

camera { location <-4,2,-6> look_at 0 angle 40 }

plane { y,-2 pigment { rgb 1 } finish { diffuse 1 brilliance 0 ambient .4} }

sphere { <0,0,0> 1000
 hollow
 pigment  { gradient y
  color_map {
   [ 0.0 color rgb <1,1,1> ]
   [ 0.5 color rgb <0,.5,1> ]
   [ 1 color rgb <0,0,0> ]
  }
  scale <1,1000,1>
 }
 finish { brilliance 0 ambient 1 }
 }



#declare redenamel =
 texture {
  pigment { rgb <.8,.1,0> }
  finish { phong .1 phong_size 80 reflection .05 }
 }

#declare whiteplastic =
 texture {
  pigment { rgb 1 }
  finish { phong 1 phong_size 40 diffuse 1 brilliance .8 }
 }

#declare chrome =
 texture {
  pigment { rgb .1 }
  finish { phong 1 phong_size 40 reflection .65 }
 }

#declare clearglass =
 texture {
  pigment { rgbf <.92,.93,.95,.94> }
  finish { phong 1 phong_size 50 reflection .15 ior 1.2 }
 }

#declare headlight =
union {
 difference {
  sphere { <0,0,0> 1 scale <1,1,2> rotate <-20,0,0> texture { redenamel } }
  sphere { <0,0,-1> 1.333 texture { whiteplastic } }
 }
 intersection {
  difference {
   sphere { <0,0,0> 1.05 }
   sphere { <0,0,0> 1 }
   scale <1,1,2>
   rotate <-20,0,0>
  }
  box { <-2,-2,-.125> <2,2,.125> }
  texture { chrome }
 }
 intersection {
  sphere { <0,0,0> 1 scale <1,1,.65> rotate <0,0,0> translate <0,0,0> }
  box { <-5,-5,-5> <5,5,.05> }
  texture { clearglass }
  normal { quilted scale .25 }
 }
}


object { headlight rotate <0,-10,0> }

Post a reply to this message

Attachments:
Download 'headlight.jpg' (13 KB)

Preview of image 'headlight.jpg'