I cancelled the previous post because I just noticed that
the image I used as reference is synthetic and not from a
CCD camera. Oh well, I guess it's close enough to a real photo.


#version unofficial megapov 0.5;

/* This scene produces image that, with gamma 2.2, matches the synthetic image of the
   Cornell box available at http://www.graphics.cornell.edu/online/box/box.jpg.
   The scene and colors are not 100% accurate and can be used for
   qualitative/artistic purposes only.
  
   June 01 2000 kar### [at] kivisalonet

*/

#declare Diffuse=1.2; // With this value brihtness=1
#declare RadQuality=2; // 1=good enough

global_settings{
  assumed_gamma 1.0
  ini_option "+qr"
  radiosity{
    pretrace_start 0.04
    pretrace_end 0.02/RadQuality
    count 100*RadQuality
    recursion_limit 3+RadQuality 
    adc_bailout 0.001
    nearest_count 4*RadQuality
    error_bound 1/RadQuality
    brightness 1.2/Diffuse
    gray_threshold 0.5     
  }
} 

#declare Finish=finish{diffuse Diffuse brilliance 0.6 ambient 0}

light_source{
  0.999*y color 4.5/Diffuse
  spotlight radius 1 falloff 90 tightness -0.6 point_at 0
  area_light <0.45, 0, 0>,<0, 0, 0.4>,20,20 adaptive 0
  fade_power 2
  fade_distance 0.45
}

#declare BaseTex=texture{pigment{rgb<0.891,0.6,0.21>}finish{Finish}}
#declare RedTex=texture{pigment{rgb<0.442,0,0>}finish{Finish}}
#declare GreenTex=texture{pigment{rgb<0.02,0.15,0.002>}finish{Finish}}

camera{
  location<0,0,-3.82>
  right x
  direction 1.365*z
  look_at <0,0,0>
}

#declare Box=box{-1,1 scale 0.001*y translate -y}

object{Box texture{BaseTex}}
object{Box rotate 90*z texture{GreenTex}}
object{Box rotate 180*z texture{BaseTex}}
object{Box rotate 270*z texture{RedTex}}
object{Box rotate -90*x texture{BaseTex}}

box{
  -0.5,0.5 translate 0.5*y scale 0.61
  rotate 17*y translate<0.32,-1,-0.38> texture{BaseTex}
}

box{
  -0.5,0.5 translate 0.5*y scale <1,2,1>*0.61
  rotate -17*y translate<-0.35,-1,0.27> texture{BaseTex}
}

box{
  -0.5,0.5 scale<0.45,0.001,0.4> translate 0.999*y
  pigment{rgb<1,1,1>} finish{ambient 1 diffuse 0} 
  no_shadow
}


-----------------------------------------------------------------------
Kari Kivisalo                                          www.kivisalo.net

Post a reply to this message

Attachments:
Download 'cornell4.jpg' (31 KB)

Preview of image 'cornell4.jpg'

From what I can see, the cieling, floor and back wall are lighting in the RL
version, and you can see the radiosity just a bit more in there too. You can
also see the green and red better on the boxes in RL. Keep refining it,
you're almost there.

Post a reply to this message

Kari Kivisalo wrote:
> 
> I cancelled the previous post because I just noticed that
> the image I used as reference is synthetic and not from a
> CCD camera. Oh well, I guess it's close enough to a real photo.
> 

I think that while you can tweak it to get pretty close to the real thing, I
don't think this serves much purpose as a measurement of POV's radiosity
quality.
In this case, you have a reliable picture of the real thing to go by. But it
seems you have to use some rather unrealistic parameters to get there. For
example diffuse 1.2 would mean that the surface reflects more light that it
receives.
My point is, you can't really make many general conclusions from these settings
since they are highly optimized for this particular scene.
        
Not that I'm critisizing your efforts - I am currently having a lot of fun with
the same thing :)

-- 
Margus Ramst

Personal e-mail: mar### [at] peakeduee
TAG (Team Assistance Group) e-mail: mar### [at] tagpovrayorg

Post a reply to this message

Margus Ramst wrote:
> But it seems you have to use some rather unrealistic parameters to get there. For
> example diffuse 1.2 would mean that the surface reflects more light that it
> receives.

My point exactly. We need more predictable implementation of radiosity
and less tweaking.

Now it's almost purely quesswork but since POV wasn't build from ground
up to produce realistic simulations I shouldn't complain. After all
realistic doesn't necessarily mean it's good looking :)

-----------------------------------------------------------------------
Kari Kivisalo                                          www.kivisalo.net

Post a reply to this message

On Sun, 04 Jun 2000 22:02:52 +0300, Kari Kivisalo <kar### [at] kivisalonet>
wrote:

>After all realistic doesn't necessarily mean it's good looking :)

I hereby let you use any photos of myself in support of your thesis :)


Peter Popov ICQ : 15002700
Personal e-mail : pet### [at] usanet
TAG      e-mail : pet### [at] tagpovrayorg

Post a reply to this message

On Sun, 04 Jun 2000 22:02:52 +0300, Kari Kivisalo <kar### [at] kivisalonet>
wrote:

>My point exactly. We need more predictable implementation of radiosity
>and less tweaking.
>
>Now it's almost purely quesswork but since POV wasn't build from ground
>up to produce realistic simulations I shouldn't complain. After all
>realistic doesn't necessarily mean it's good looking :)

However, more realistic renderings tend to be more predictible, at
least in my experience. There have been several scenes that I have
abandoned in the past, because I couldn't reliably predict the results
of the lighting, based upon my experiences with real-world lighting.

POV is certainly getting better in that respect, and I hope the trend
continues. I can easily remember a time before area lights, light
fading, radiosity, photons, etc.   Realistic lighting was nearly
impossible for me to achieve at that time, except for a few special
cases that didn't need any of the "advanced" lighting techniques.

I think trying to make POV-Ray as physically accurate as possible, is
a good goal to strive for. One can always enter some unusual
parameters to achieve unusual or unnatural effects, if so desired.

Later,
Glen Berry

7no### [at] ezwvcom
(Remove the "7" to reply via email.)

Post a reply to this message