Hello everybody. Attached is an image showing off a new pigment I found
today. I've been wanting to create a maze-like pigment for some time
now. Can you guess how it was done?

Here are some hints:
    It was made totally in PovRay; no paint programs were used.
    It was made with MegaPov (Superpatch works too).
    It's not a huge, complex iso function, although it uses small
functions for simple tasks you could already do in pov (so the functions
really don't matter).

Good evening~

--
Samuel Benge

E-Mail: STB### [at] aolcom

Visit the still unfinished isosurface tutorial:
http://members.aol.com/stbenge

Post a reply to this message

Attachments:
Download 'mazepigm.jpg' (83 KB)

Preview of image 'mazepigm.jpg'

"SamuelT." <STB### [at] aolcom> wrote in message
news:38A0D839.371F1B4E@aol.com...
> Hello everybody. Attached is an image showing off a new pigment I found
> today.

    Oooo...

>Can you guess how it was done?

    Not a chance. I don't see any repeats, are there any?

Post a reply to this message

On Tue, 08 Feb 2000 19:00:10 -0800, SamuelT. wrote:
>Hello everybody. Attached is an image showing off a new pigment I found
>today. I've been wanting to create a maze-like pigment for some time
>now. Can you guess how it was done?

It looks kinda like this, but mine doesn't have all the loops, and it
has a definite diagonal tendency.

camera {location 20*y sky y look_at <15,0,15>}
light_source {20*y rgb 1}

plane {y,0
  pigment {
    crackle solid metric 1 
    pigment_map {
      [.5 gradient x color_map{[.5 rgb 0][.5 rgb 1]} warp{repeat x}]
      [.5 gradient z color_map{[.5 rgb 1][.5 rgb 0]} warp{repeat z}]
    } 
  }
}

-- 
These are my opinions.  I do NOT speak for the POV-Team.
The superpatch: http://www2.fwi.com/~parkerr/superpatch/
My other stuff: http://www2.fwi.com/~parkerr/traces.html

Post a reply to this message

On 9 Feb 2000 01:26:00 -0500, Ron Parker wrote:
>It looks kinda like this, but mine doesn't have all the loops, and it
>has a definite diagonal tendency.

Or this version, slightly loopier but with the odd broken piece:

plane {y,0
  pigment {
    bozo  
    pigment_map {
      [.5 gradient x 
          color_map{[.25 rgb 0][.25 rgb 1][.75 rgb 1][.75 rgb 0]} 
          warp{repeat x} scale sqrt(2) rotate 45*y ]
      [.5 gradient x 
          color_map{[.25 rgb 0][.25 rgb 1][.75 rgb 1][.75 rgb 0]} 
          warp{repeat x} scale sqrt(2) rotate -45*y]
    }                        
    scale 100                   
    warp {repeat x offset 50*y}
    warp {repeat z offset 60*z} 
    warp {reset_children}
  }
}

-- 
These are my opinions.  I do NOT speak for the POV-Team.
The superpatch: http://www2.fwi.com/~parkerr/superpatch/
My other stuff: http://www2.fwi.com/~parkerr/traces.html

Post a reply to this message

All I know is that pigments can be made into new patterns but I don't see how
you got a seemingly infinitely changing maze out of it.  It's great, never seen
one before.

Bob

"SamuelT." <STB### [at] aolcom> wrote in message news:38A0D839.371F1B4E@aol.com...
| Hello everybody. Attached is an image showing off a new pigment I found
| today. I've been wanting to create a maze-like pigment for some time
| now. Can you guess how it was done?
|
| Here are some hints:
|     It was made totally in PovRay; no paint programs were used.
|     It was made with MegaPov (Superpatch works too).
|     It's not a huge, complex iso function, although it uses small
| functions for simple tasks you could already do in pov (so the functions
| really don't matter).
|
| Good evening~
|
| --
| Samuel Benge
|
| E-Mail: STB### [at] aolcom
|
| Visit the still unfinished isosurface tutorial:
| http://members.aol.com/stbenge
|
|


--------------------------------------------------------------------------------

Post a reply to this message

Excellent - at first I thought it was a bitmap repeated - but I didn't see
any repeating patterns.

Will you be sharing your pigment code with the rest of us?

Mike

> Hello everybody. Attached is an image showing off a new pigment I found
> today. I've been wanting to create a maze-like pigment for some time
> now. Can you guess how it was done?
>
> Here are some hints:
>     It was made totally in PovRay; no paint programs were used.
>     It was made with MegaPov (Superpatch works too).
>     It's not a huge, complex iso function, although it uses small
> functions for simple tasks you could already do in pov (so the functions
> really don't matter).
>
> Good evening~
>
> --
> Samuel Benge
>
> E-Mail: STB### [at] aolcom
>
> Visit the still unfinished isosurface tutorial:
> http://members.aol.com/stbenge
>
>


----------------------------------------------------------------------------
----

Post a reply to this message

I'm almost thinking that you found a way to randomize a checke pattern with
limiting the steps to 90 degree turns when caclulcation the tubulence... but
I'm probably way off.


"SamuelT." wrote:

> Hello everybody. Attached is an image showing off a new pigment I found
> today. I've been wanting to create a maze-like pigment for some time
> now. Can you guess how it was done?
>
> Here are some hints:
>     It was made totally in PovRay; no paint programs were used.
>     It was made with MegaPov (Superpatch works too).
>     It's not a huge, complex iso function, although it uses small
> functions for simple tasks you could already do in pov (so the functions
> really don't matter).
>
> Good evening~
>
> --
> Samuel Benge
>
> E-Mail: STB### [at] aolcom
>
> Visit the still unfinished isosurface tutorial:
> http://members.aol.com/stbenge
>
>   ------------------------------------------------------------------------
>  [Image]

--
Josh English
eng### [at] spiritonecom
"May your hopes, dreams, and plans not be destroyed by a few zeros."

Post a reply to this message

On Tue, 08 Feb 2000 19:00:10 -0800, SamuelT. wrote:
>Hello everybody. Attached is an image showing off a new pigment I found
>today. I've been wanting to create a maze-like pigment for some time
>now. Can you guess how it was done?

Okay, I'm going to assume this is pretty much it until you say otherwise:

#macro MazePigment(Pig1,Pig2) 
  #local Pig3=pigment {
    gradient x 
    pigment_map {[.25 Pig1][.25 Pig2][.75 Pig2][.75 Pig1]} 
    warp {repeat x} scale sqrt(2) rotate 45*y  
  }
  function { noise3d(floor(x)+.5,floor(y)+.5,floor(z)+.5) }
  pigment_map {   
    [.5 Pig3 ]
    [.5 Pig3 rotate 90*y ]
  }
#end

camera {location 80*y sky z look_at 0}
light_source {80*y rgb 1}

plane {y 0
  pigment {
    MazePigment(pigment{color rgb <.5,.5,1>}, pigment {color rgb 0})
  }
}

-- 
These are my opinions.  I do NOT speak for the POV-Team.
The superpatch: http://www2.fwi.com/~parkerr/superpatch/
My other stuff: http://www2.fwi.com/~parkerr/traces.html

Post a reply to this message

It does repeat.

Ron, your' guesses were excellent! You had the basic idea down, but not
the procedure. I like your first try at it best, although it does have a
diagonal tendancy, and I could not remove it. Best thing about yours is
that it doesn't repeat. I didn't know metric did that to crackle.

Well, here's mine in macro form. It may need to be edited if you paste
it into pov.

// Maze( M_Dim, M_Complex, M_Randseed )
//
// M_Dim is the dimensions for the tile. '4' would let you place it on a
// 4-unit square cube
//
// M_Complex is how complex you want it. Values range from 0 to 2.
// good values are from 1 to 2
//
// M_Randseed is just the seed value for the maze. Enter any value to
// see different patterns

#version unofficial MegaPov .3;    // needed for MegaPov .4 users

camera{ location<0,10,-15> look_at 0 angle 40 rotate y*-30 }

light_source{ <100,200,100>,1 }

background{ <.4 .7 1> }

#macro Maze( M_Dim, M_Complex, M_Randseed )
 #local M_Dim=M_Dim*8;
 #local M_Rand=M_Dim/20
 #local M_Pat=
  function{
   pigment{
    image_map{
     pattern M_Dim, M_Dim{ function noise3d(x,y,z) scale( .25/M_Rand
)/M_Complex translate y*rand( seed( M_Randseed ) ) }
     map_type 0    //include 'once' to test the tiling
    }
    translate<-.5, -.5, -.5> rotate x*90 scale M_Dim/4
   }
  }
 #local M_Pigm=
  function{
   pigment{
    function M_Pat( x, y, z ) scale .5
    pigment_map{
     [.5 function x*2 sine_wave color_map{ [.5 rgb 0][.5 rgb 1] } ]
     [.5 function z*2 sine_wave color_map{ [.5 rgb 0][.5 rgb 1] } ]
    }
   }
  }
 function{ M_Pigm( x, y, z ) }
#end

box{<-4,-1,-4>,<4,1,4>
 pigment{ Maze( 8, 1.25, 13598 ) }
}


--
Samuel Benge

E-Mail: STB### [at] aolcom

Visit the still unfinished isosurface tutorial: http://members.aol.com/stbenge

Post a reply to this message

That is so neat.  And a-mazing you could ever come up with a similar pattern as
well as that too.
Only thing I can see unmaze-like about both Sams and Rons is they have many
closed paths.  Most mazes I've ever seen don't a completely sealed off sections
like these do.  But who cares, it's a great pattern.

Bob

"Ron Parker" <ron### [at] povrayorg> wrote in message
news:slr### [at] rongwmicrocom...
| On Tue, 08 Feb 2000 19:00:10 -0800, SamuelT. wrote:
| >Hello everybody. Attached is an image showing off a new pigment I found
| >today. I've been wanting to create a maze-like pigment for some time
| >now. Can you guess how it was done?
|
| Okay, I'm going to assume this is pretty much it until you say otherwise:
|
| #macro MazePigment(Pig1,Pig2)
|   #local Pig3=pigment {
|     gradient x
|     pigment_map {[.25 Pig1][.25 Pig2][.75 Pig2][.75 Pig1]}
|     warp {repeat x} scale sqrt(2) rotate 45*y
|   }
|   function { noise3d(floor(x)+.5,floor(y)+.5,floor(z)+.5) }
|   pigment_map

|     [.5 Pig3 ]
|     [.5 Pig3 rotate 90*y ]
|   }
| #end
|
| camera {location 80*y sky z look_at 0}
| light_source {80*y rgb 1}
|
| plane {y 0
|   pigment {
|     MazePigment(pigment{color rgb <.5,.5,1>}, pigment {color rgb 0})
|   }
| }
|
| --
| These are my opinions.  I do NOT speak for the POV-Team.
| The superpatch: http://www2.fwi.com/~parkerr/superpatch/
| My other stuff: http://www2.fwi.com/~parkerr/traces.html

Post a reply to this message