|
 |
On 13-10-2013 14:33, posfan12 wrote:
> Can anyone recommend a good finish for seawater? I'm using the following but I
> think the reflection is too high.
>
> finish
> {
> ambient 0.45
> diffuse 0.55
> reflection 0.3
> }
>
>
> Mike
>
>
For what it's worth, I use the following for my Gancaloon (and others)
water:
finish {
conserve_energy
diffuse 0.2
ambient 0
reflection {0.01, 0.2 fresnel on metallic 0}
}
In combination with an interior{} of course.
Marc Jacquier used the following finish for his sea water:
finish {
ambient 0.15
diffuse 0.0
brilliance 5.0
phong 1.0
phong_size 90.0
specular 0.4
roughness 0.01
conserve_energy
reflection {
.1,
.9
falloff 2
}
}
Thomas
Post a reply to this message
|
|
|
|
> Can anyone recommend a good finish for seawater? I'm using the following but I
> think the reflection is too high.
>
> finish
> {
> ambient 0.45
This is an extremely large value, MUCH to large.
> diffuse 0.55
Also to large for water.
> reflection 0.3
Constant reflection will never seems realistic for water, or most
objects, you need to use variable reflection.
> }
>
>
> Mike
>
>
For water, I don't use only the finish, I also use the pigment and an
interior statement as follow (as a full material):
material{
texture{
pigment{rgbt 1}
finish{
ambient 0
diffuse 0.15
reflection{ 1 fresnel}
conserve_energy
specular 1 roughness 0.001
}
}
interior{
ior 1.34
dispersion 1.02
fade_color rgb<0.7, 0.8, 0.95>
fade_distance 50 // adjust as needed
fade_power 1 // or 1001
}
}
reflection{1 fresnel} goes from zero, or very small, for perpendicular
rays and up to 1, or fully reflective, for tengential rays. Higher iors
tend to result in stronger reflection, even for perpendicular rays.
conserve_energy ensure that reflected and transmited rays are coerent.
When using fresnel reflection, it's essential to have an ior. Sea water
ior is slightly larger than that of fresh water that have an ior of
1.33. Use 1.34 (slightly salty) to 1.37 (brine) to reflect variation in
salinity.
Different light colours are not refracted the same way, use dispersion
to reflect that. Keep the dispersion value larger than but close to 1 to
have realistic value.
If you don't have any details showing through the water, you can omit
the dispersion.
Next, the colour of the water is provided by using colour fading.
You need to adjust fade_distance acording to the scene scale.
I prefer using fade_power 1 (linear), but others insist that fade_power
1001 (exponential) is closer to a physicaly correct representation.
For water, and most essentialy transparent objects, keep ambient to zero
and diffuse lower that usual. This also apply to reflective surfaces.
Alain
Post a reply to this message
|
|
