I have made a blob asteroid, but it has cracks in it. The cracks appear
under v3.6 but not v3.0. Any ideas why or how to fix it?

(PS sturm doesn't do anything)

Evan

Post a reply to this message

You're probably going to have to post an image plus source code for 
anyone to work out why it's doing this...

Post a reply to this message

Andrew C on Mozilla <voi### [at] devnull> wrote:
> You're probably going to have to post an image plus source code for
> anyone to work out why it's doing this...

Here is the source... I called it (an include file) like this...

#declare AstObjs1 = 100;
#declare AstObjs2 = 0;
#declare AstSeed1 = 0;
object { #include "astroid3.inc" texture { AstTex } scale 800 rotate 0*z
translate 3000*y-500*x }


Here is astroid3.inc

#ifndef (AstSeed1)
#declare AstSeed1 = 911;
#end

#ifndef (AstSeed2)
#declare AstSeed2 = 912;
#end

#ifndef (AstSeed13)
#declare AstSeed3 = 913;
#end

#ifndef (AstObjs1)
#declare AstObjs1 = 50;
#end

#ifndef (AstObjs2)
#declare AstObjs2 = 50;
#end

#ifndef (AstObjs3)
#declare AstObjs3 = 50;
#end

#ifndef (AR1) #declare AR1 = seed(AstSeed1); #end
#ifndef (AR2) #declare AR2 = seed(AstSeed2); #end
#ifndef (AR3) #declare AR3 = seed(AstSeed3); #end

blob {
 threshold 0.8

 #declare AL = 0;
 #while (AL < AstObjs1)
  sphere { <0.5, 0, 0>, 0.5, 0.25+0.75*rand(AR1)
   rotate 360*rand(AR1)*x+360*rand(AR1)*y+360*rand(AR1)*z
  }
 #declare AL = AL + 1;
 #end

 #declare AL = 0;
 #while (AL < AstObjs2)
  sphere { <0, 0, 0>, 0.25, -0.75-0.25*rand(AR2)
   scale 0.75*x+y+z
   translate 0.75*x
   rotate 360*rand(AR2)*x+360*rand(AR2)*y+360*rand(AR2)*z
                }
 #declare AL = AL + 1;
 #end

 sturm
}

Post a reply to this message

The cracks disappear if I replace spheres with very short cylinders. Of
course it takes 3 times longer to render!

Post a reply to this message

> The cracks disappear if I replace spheres with very short cylinders. Of
> course it takes 3 times longer to render!
> 
> 

All I get is plain black screen...
What about giving the camera and light source too (along with AstTex...)


-- 




l'habillement, les chaussures que le maquillage et les accessoires.

Post a reply to this message

Le Forgeron <jgr### [at] freelocalhost> wrote:

>
> > The cracks disappear if I replace spheres with very short cylinders. Of
> > course it takes 3 times longer to render!
> >
> >
>
> All I get is plain black screen...
> What about giving the camera and light source too (along with AstTex...)

I suppose that wasn't very helpful... Here it is



camera {
  location  0
  direction 1*z
  up        z
  sky       z
  right     4/3*x
  look_at   y
}

light_source {
  <0.5,-0.5,0.5>*10000000
  color rgb 1
}

#declare AstTex =
texture {
 pigment {
   bozo
   turbulence 1
  //frequency 2
  octaves 6
  omega 0.85
  color_map {
     [0.0 color rgb 0.35]
   [0.66 color rgb 0.65]
   [1 color rgb 0.75]
   }
  scale 0.2
 }
 finish { ambient 0.2 diffuse 0.8 }
}

#declare AstObjs1 = 150;
#declare AstObjs2 = 0;
#declare AstSeed1 = 0;

#ifndef (AstSeed1)
#declare AstSeed1 = 0;
#end

#ifndef (AstSeed2)
#declare AstSeed2 = 1;
#end

#ifndef (AstSeed13)
#declare AstSeed3 = 2;
#end

#ifndef (AstObjs1)
#declare AstObjs1 = 50;
#end

#ifndef (AstObjs2)
#declare AstObjs2 = 50;
#end

#ifndef (AstObjs3)
#declare AstObjs3 = 50;
#end

#ifndef (AR1) #declare AR1 = seed(AstSeed1); #end
#ifndef (AR2) #declare AR2 = seed(AstSeed2); #end
#ifndef (AR3) #declare AR3 = seed(AstSeed3); #end

blob {
 threshold 0.8

 #declare AL = 0;
 #while (AL < AstObjs1)
 sphere { <0.5, 0, 0>, 0.5, 0.25+0.75*rand(AR1)
                scale x+y/4*3+z/4*3
  rotate 3600*rand(AR1)*x+3600*rand(AR1)*y+3600*rand(AR1)*z
 }
 #declare AL = AL + 1;
 #end

 #declare AL = 0;
 #while (AL < AstObjs2)
 sphere { <0, 0, 0>, 0.25, -0.75-0.25*rand(AR2)
  scale 0.75*x+y+z
  translate 0.75*x
  rotate 3600*rand(AR2)*x+3600*rand(AR2)*y+3600*rand(AR2)*z
        }
 #declare AL = AL + 1;
 #end

 sturm
 texture { AstTex } scale 800 rotate 0*z translate 2000*y
}

Post a reply to this message

> Le Forgeron <jgr### [at] freelocalhost> wrote:

>>
>> > The cracks disappear if I replace spheres with very short
>> > cylinders. Of course it takes 3 times longer to render!
>> >
>> >
>>
>> All I get is plain black screen...
>> What about giving the camera and light source too (along with
>> AstTex...) 
> 
> I suppose that wasn't very helpful... Here it is
> 
Good.

It seems it's a precision issue due to the scale.

Changing the scale 800 to scale 8, and multiplying the camera's direction 
by 100... just make the crack disappears on my 3.6.0 (will update soon).




-- 




l'habillement, les chaussures que le maquillage et les accessoires.

Post a reply to this message

Le Forgeron <jgr### [at] freelocalhost> wrote:
> It seems it's a precision issue due to the scale.

That gave me the idea of scaling the individual components instead of the
whole blob, which seems to fix the problem. Thanks. Of course it doesn't
explain why using cylindrical components didn't have the same problem...

Post a reply to this message