In article <3A5E61BB.DAA182F6@209software.com>, bry### [at] 209softwarecom 
wrote:

> I want a unit sphere that looks like a glowing ball of yellow or green
> gas.  Once again, I can't get it to show up at all.  it's always
> completely invisible.

This is the wrong newsgroup...a better choice might have been 
povray.newusers or povray.advanced-users (I'm forwarding this thread to 
povray.advanced-users). This group is for posting of scene files...see 
the posts in povray.announce.frequently-asked-questions for more 
information on these groups.

As for your problem...it sounds like you are just using too low of a 
density, or have the media in a non-hollow object. Make sure that the 
media container itself has "hollow" specified, and that it isn't inside 
any non-hollow objects (and remember that objects like planes do have an 
inside, make sure you are on the correct side). If all this is set up 
correctly, try increasing the density of the media. Media density is 
controlled by the intensity of it's color...just brighten the color to 
make it more dense. I usually use separate color and density values, 
like this: emission COLOR*DENSITY

-- 
Christopher James Huff
Personal: chr### [at] maccom, http://homepage.mac.com/chrishuff/
TAG: chr### [at] tagpovrayorg, http://tag.povray.org/

<><

Post a reply to this message

>
> > I want a unit sphere that looks like a glowing ball of yellow or green
> > gas.  Once again, I can't get it to show up at all.  it's always
> > completely invisible.
>

// try something like this (note the comments about megapov)
#version unofficial MegaPov 0.5; // remove this line if not using megapov

#include "colors.inc"
light_source{<0,0,0> White translate <-20, 20, -20>}
camera{location  <0,0,-50> look_at <0,0,0>}

sphere{0, 20
  pigment{rgbf 1}
  finish{reflection 0.1 specular 0.5 roughness 0.001}
  hollow on
  interior{
    ior 1.6

    media{
      method 3 // replace this line with "intervals 50" if not using megapov
      emission rgb<0.5,0.5,1>*0.125
      absorption rgb<1,1,0.5>*0.125
      density{
        agate scale 10
        density_map{
          [0.99 Black]
          [0.99 White]
        }
      }
    }

    media{
      method 3 // replace this line with "intervals 50" if not using megapov
      emission rgb<1,0.5,1>*.25
      absorption rgb<0.5,1,0.5>*.25
      density{
        spherical scale 10
        density_map{
          [0.0 Black]
          // [0.1 Black]
          [1.0 wrinkles scale 5]
        }
      }
    }

  }
}

Post a reply to this message

by the way, I found out what my problem was... I didn't use "hollow".

Tom Melly wrote:

> >
> > > I want a unit sphere that looks like a glowing ball of yellow or green
> > > gas.  Once again, I can't get it to show up at all.  it's always
> > > completely invisible.
> >
>
> // try something like this (note the comments about megapov)
> #version unofficial MegaPov 0.5; // remove this line if not using megapov
>
> #include "colors.inc"
> light_source{<0,0,0> White translate <-20, 20, -20>}
> camera{location  <0,0,-50> look_at <0,0,0>}
>
> sphere{0, 20
>   pigment{rgbf 1}
>   finish{reflection 0.1 specular 0.5 roughness 0.001}
>   hollow on
>   interior{
>     ior 1.6
>
>     media{
>       method 3 // replace this line with "intervals 50" if not using megapov
>       emission rgb<0.5,0.5,1>*0.125
>       absorption rgb<1,1,0.5>*0.125
>       density{
>         agate scale 10
>         density_map{
>           [0.99 Black]
>           [0.99 White]
>         }
>       }
>     }
>
>     media{
>       method 3 // replace this line with "intervals 50" if not using megapov
>       emission rgb<1,0.5,1>*.25
>       absorption rgb<0.5,1,0.5>*.25
>       density{
>         spherical scale 10
>         density_map{
>           [0.0 Black]
>           // [0.1 Black]
>           [1.0 wrinkles scale 5]
>         }
>       }
>     }
>
>   }
> }

--
Bryan Valencia
Software Services - Making Windows Scream
http://www.209software.com
mailto:bry### [at] 209softwarecom

Post a reply to this message