I'm trying to make a realistic looking sky, so far without too much success.
I'm fairly new to Pov-Ray so i'm probably doing it the wrong way or
something.

So far i've used the built in sky_sphere, but the problem with this is that
the clouds just don't look realistic because there is no perspective.
Someone suggested having a seperate blue background sky sphere and a smaller
cloud sphere with a partially transparent color map and then flattening
both. They also suggested adding fog to the scene to further increase the
realism of the scene.

If anyone has any experience in this area could they please make some
suggestions and post some suitable code? I'm beginning to lose the will to
live!

Thanks
Paul

Post a reply to this message

ranger5 wrote:

> If anyone has any experience in this area could they please make some
> suggestions and post some suitable code? I'm beginning to lose the will to
> live!

In the two scene files groups on this news server have been posted
a few clouds scene files. A couple of them are quite realistic using
POV-Ray's medai feature. Just search for clouds in the subject lines
in those groups and you should find a starting point. Also the IRTC
entries often have the source available for study. You might try
browsing some of the out door subjects looking for realistic skies
and see if they included the source with the image. It is a valuable
resource in this regard. http://www.irtc.org

-- 
Ken Tyler - 1400+ POV-Ray, Graphics, 3D Rendering, and Raytracing Links:
http://home.pacbell.net/tylereng/index.html http://www.povray.org/links/

Post a reply to this message

Hey dude!  I feel your pain.  Here's a reasonable alternative to media.  Works
best for sunset or evening pics.

//Start
#declare Color = <1,.625,.25>
#declare LightColor = (Color+.5)/2

fog {fog_type 2 distance 150000 rgb LightColor transmit .25
fog_offset 0
fog_alt 2500
}
fog {
distance 1500 rgb <.9,.85,1>/2 transmit .175
}
#declare Bright = 24
#declare DesertSky =
sphere {0,1
//Back Drop
texture {
finish {ambient 2 diffuse 0}
pigment {
gradient y
color_map {
[0 rgb 1.5*Bright*Color]
[.5 rgb <.5,.675,1>/2]
}
}
scale 1/<2,.5,2>
}
texture {
finish {ambient 1 diffuse 0}
pigment {
bozo
color_map {
[.5 rgb <.5,.675,1> transmit 1 ]
[1 rgb 1*Bright*Color transmit .45]
}
translate 1
scale .5
turbulence <2,1,2>
scale 10
warp {turbulence <2,1,2>}
scale 1/10

lambda 2
scale <1,.75,1>
}
scale .25
}
texture {
finish {ambient 1 diffuse 0}
pigment {
bozo
color_map {
[.5 rgb <.5,.675,1> transmit 1 ]
[1 rgb 1*Bright*Color transmit .45]
}
translate 1
scale .25
turbulence 1
scale 10
warp {turbulence <2,1,2>}
scale 1/10
lambda 4
scale <1,.75,1>
}
scale .5
}
texture {
finish {ambient 1 diffuse 0}
//Back Shadow
pigment {
bozo
color_map {
[.65 rgb <.375,.5,1> transmit 1]
[.85 rgb 2*Bright*Color]
}
turbulence .25
scale 10
warp {turbulence <2,1,2>/4}
scale 1/10
scale .25
translate -.025*y
translate .05*x
}
scale .5
}
texture {
finish {ambient 1 diffuse 0}
//Light Part
pigment {
bozo
pigment_map {
[.65 rgb <.5,.675,1>/1.5 transmit 1]
[.775 bozo color_map {[0 rgb .875][1 rgb 2*Bright*Color]} turbulence .5 scale
.25]
}
turbulence .25
scale 10
warp {turbulence <2,1,2>/4}
scale 1/10
scale .25
}
scale .5
}
texture {
finish {ambient 1 diffuse 0}
//Dark Part
pigment {
bozo
color_map {
[.65 rgb <.5,.675,1> transmit 1]
[.975 rgb 0 ]
}
turbulence .25
scale 10
warp {turbulence <2,1,2>/4}
scale 1/10
scale .25
translate -.06*y
translate .1*x
}
scale .5
}
texture {
finish {ambient .5 diffuse 0}
//Back Shadow
pigment {
bozo
color_map {
[.65 rgb <.375,.5,1> transmit 1]
[.85 rgb 2*Bright*Color]
}
turbulence .375
scale 10
warp {turbulence <2,1,2>/3}
scale 1/10
scale .125
translate -.025*y
translate .05*x
}
scale .5
}
texture {
finish {ambient .5 diffuse 0}
//Light Part
pigment {
bozo
pigment_map {
[.65 rgb <.5,.675,1>/1.5 transmit 1]
[.775 bozo color_map {[0 rgb .875][1 rgb 4*Bright*Color]} turbulence .5 scale
.25]
}
turbulence .375
scale .125
}
scale .5
}
texture {
finish {ambient .5 diffuse 0}
//Dark Part
pigment {
bozo
color_map {
[.65 rgb <.5,.675,1> transmit 1]
[.975 rgb <.1,.1,.2> transmit .675/2]
}
turbulence .375
scale 10
warp {turbulence <2,1,2>/3}
scale 1/10
scale .125
translate -.05*y
translate .08*x
}
scale .5
}
texture {
finish {ambient 1 diffuse 0}
pigment {
gradient y
color_map {
[0 rgb <.5,.675,1>*1.5 transmit .25]
[.25 rgb <.5,.675,1>/1.5 transmit 1]
}
}
}
texture {
finish {ambient 1 diffuse 0}
pigment {
rgb <.25,.25,1>/4 transmit .25}
}

scale 2000000
scale <4,.5,4>
hollow on
}
object {DesertSky rotate 45*y scale -x}
//End

Do hope this helps.

--
H.E. Day

Post a reply to this message

On Sun, 16 Apr 2000 13:30:53 -0700, "H.E. Day" <hed### [at] fcinet> wrote:

>Hey dude!  I feel your pain.  Here's a reasonable alternative to media.  Works
>best for sunset or evening pics.

<snipped lotsa useful code>

Hey man, are you taking the same code indentation course that Ken
does? :)


Peter Popov ICQ : 15002700
Personal e-mail : pet### [at] usanet
TAG      e-mail : pet### [at] tagpovrayorg

Post a reply to this message

Peter Popov wrote:

> Hey man, are you taking the same code indentation course that Ken
> does? :)

Looks perfectly natural to me ;^ }

-- 
Ken Tyler - 1400+ POV-Ray, Graphics, 3D Rendering, and Raytracing Links:
http://home.pacbell.net/tylereng/index.html http://www.povray.org/links/

Post a reply to this message