On Sun, 09 May 2004 10:54:43 +0100, Andrew C on Mozilla <voi### [at] devnull> 
wrote:

> Hi folks.
>
> This is supposed to be a an extreme closeup of a small gemstone (a few
> mm across), set in a gold setting. But it looks nothing like that - and
> I can't figure out why.
>
> The stone doesn't look remotely gem-like. Can't figure that out. It's
> transparent, reflective, and reflective. What am I missing?
>
> The setting doesn't look like gold. I've fiddled with brilliance,
> specular, roughness, reflection, and turned on metallic (as well as
> conserve_energy). Still doesn't look remotely like metal. Why?
>
> Also can't figure out why the metal setting apparently isn't resulting
> in any photons. (It makes the photon process hundreds of times slower -
> that is, I had to multiply the photon spacing a few hundred times to get
> it to render this year.)
>
> This was supposed to end up being a single link in a bracelet - but it
> looks so rubbish I hadn't get that far yet.
>

I was playing with isosurfaces some while back and produced this if it 
helps:
//start code
#include "glass.inc"
#include "textures.inc"

global_settings{
photons{count 10000}
}

camera{
location <-2,5,-5>
look_at 0}
plane{y,-2 pigment{
agate scale 20 color_map{[0 rgb 0.5][1 rgb 1]} }}
light_source{<0,10,10> rgb 1
photons{reflection on refraction on}
}

#declare RubyFace=
isosurface {
function {max(abs(x)+abs(y)-3
,abs(z)+abs(y)-3
,abs(x)+abs(y)+abs(z)-4
)}
contained_by {box{-2, 2}}
max_gradient 2
scale y*0.5
}

#declare RubyHalf=
difference{
object{RubyFace}
box{-3,<3,0.2,3>}
translate y*-0.201
}

merge{
object{RubyHalf}
object{RubyHalf scale <1,-1,1>}
pigment{Col_Glass_Ruby}
finish{specular 0.5 reflection 0.2}
interior{ior 1.7}
photons{target refraction on reflection on}
}

#declare i=-13;
#declare Beads=
union{
#while(i<14)
sphere{0,0.1 texture{Gold_Metal} translate <-2.1,0.2,i*0.1>}
#declare i=i+1;
#end
}

#declare BeadBand=
union{
object{Beads}
object{Beads scale y*-1}
box{0,<0.2,0.2,2.8> texture{Gold_Metal} translate <2,-0.1,-1.4>}
}

object{BeadBand}
object{BeadBand scale x*-1}
//end code

The underside facets make a big difference

--
Phil Cook

-- 
All thoughts and comments are my own unless otherwise stated and I am 
happy to be proven wrong.

Post a reply to this message