|
|
On Sun, 02 Jul 2000 22:23:03 -0500, Hookflash <hoo### [at] hotmailcom>
wrote:
>P.S. I'm having trouble lighting my scenes... What are the most common
>methods used (I remember hearing something about "3-point lighting",
>whatever that means)?
Here's what I usually use for showing off a model:
#declare Brightness = 1; // tweak to fit;
// #declare High_Quality = on; // uncomment if needed
light_source
{ <0,100,0> color White*0.5*Brightness
#ifdef (High_Quality)
area_light
20*x, 20*z,
5, 5
adaptive 1
jitter
#end
spotlight
point_at 0
radius 5
falloff 13
tightness 100
}
light_source
{ <100,100,-100> color rgb <1,0.9,0.8>/2*Brightness
#ifdef (High_Quality)
area_light
15*sqrt(2)*(x+z), 30*x,
5, 5
adaptive 1
jitter
#end
}
light_source
{ <0,40,60> color rgb <0.8,0.9,1>/2*Brightness
#ifdef (High_Quality)
area_light
10*sqrt(2)*(x-z), 20*x,
5, 5
adaptive 1
jitter
#end
spotlight
point_at 0
radius 5
falloff 15
tightness 10
}
Seems to work OK for models that fit a sphere { 0, 10 }.
Peter Popov ICQ : 15002700
Personal e-mail : pet### [at] usanet
TAG e-mail : pet### [at] tagpovrayorg
Post a reply to this message
|
|