tho### [at] trfde news:4076ddf6$1@news.povray.org

> Sadly, your scene just fails to render for me because 

It uses only 2 files *.inc, what was the error message?

> For all I know it could be a problem in your complex scene.

Anyway, I found what was the problem, while cleaning up scene for 
bug report (I've shorten it to 40 lines + comments.

This looks loke a realy rare bugs, it's quite funny actualy, the bug is:
a problem with anti-alias of reflection of 2 intersecting media 
containers, if they are putted in bigger hollow object, and when 
media color is very bright.

As for the scene - there are 2 torussed filled with emission media. 
They intersect. Intersection point is beeing reflected in blue object 
behind. When antialias is on, then random pixels near reflection of 
intersection are white.

Scene usses a big hollow sphere (used as background/skysphere in 
oryginal scene) it is needed if we want to see the bug, AFAIK.

So I'm guessing bug has something to do both with media and antialias
 color-clipping.

Should I post .pov file and example render of shorten code to 
p.beta-test.binary ?



The scene source (no external files this time)



==============================================

// (C) 2004 Rafal Maj Raf256 www.raf256.com/povray/
// raf256 povray bug 04/0001 version 001 - breached from: IFJ Logo A ver 0.40.10
(miles >7)
// news.povray.org: Message-ID: <Xns94C6BD1A1EE04raf256com@203.29.75.35>

// reproduce bug:
// (((0))) render with AA to see bug: +w512 +h384 +a0.03 +am2 +r2
// (((1))) enclose scene in big hollow primitive like sphere
// (((2))) use bright emitting media
// (((3))) allow media to be reflected in some other object
// (((4))) have 2 media containers intersecting

#local USE_BIG_SPHERE = 1; // (((1))) set to 1 to see bug

camera { location -30*z look_at 0 translate <-4,3,0>  angle 30 }
global_settings { max_trace_level 20 }
background { rgb .5 }

#if (USE_BIG_SPHERE) sphere { 0 2000 pigment {  rgb .4 }  finish { diffuse 0 ambient
.82 }  hollow } #end

light_source { <-400,700,-600> rgb 1  }

difference {    
  sphere { 0 0.12 scale <1,1,.5> }
  sphere { 0 0.122 scale <1,1,1> translate -z*0.10 }
  
  translate  <-0.2,0,0> + <0.10,0.50,0>
  translate <-.1,-.2,0>  scale 20*<1 , 1, .3>  
  
  pigment { rgb <0.25, 0.65, 1.0> }
  finish { reflection { .23 .38 metallic .35 } } // (((3)))
}
  

union {  
  #macro makeTrak(RX,RY,RZ)
    torus { 3 0.020 rotate x*RX rotate +y*RY rotate z*RZ  hollow 
      pigment { rgbf 1 }
      interior { media {  emission <1,.4,.01>*20 /* (((2))) */  } }
    }
  #end
  
  makeTrak(90,90,  0)
  makeTrak(90,90, 60) // (((4)))
  
  pigment { rgbft <0.70, 0.70, 0.30, 0.40, .20> }
  finish { diffuse 0 ambient .8 }
  interior { media { emission 0.4*<1,.5,.1> } }     
    
  translate <-4,6,0> - z*1.30 + <0.21, -0.22, 0>
}

==============================================


-- 
http://www.raf256.com/3d/
Rafal Maj 'Raf256', home page - http://www.raf256.com/me/
Computer Graphics

Post a reply to this message