|
![](/i/fill.gif) |
spr### [at] web de news:402### [at] web de
> sorry, but can't see the .pov file in netscape-newsreader
just copy/paste into *.pov :
/*
A-00114 Grid
by Rafal Maj 'Raf256'
http://www.raf256.com/
http://www.raf256.com/3d/pov/
mailto:raf### [at] raf256 com
*/
#declare QQ_MEDIA = 1;
#declare CFG_FOG = 0.30; // <-- for strength
global_settings {
assumed_gamma 2
max_trace_level 50
}
camera {
location <-70, 81, -90>*1.5 // <-- camera X,Y,Z positon (left, up, back)
#local P=<-3,5,5>; // <-- look at X,Y,Z
look_at P
angle 57
#if (1)
focal_point P
aperture 1
blur_samples 20
variance 1/64
confidence 0.98
#end
}
fog {
color rgb <.2,.25,.3>*.5
distance 100/CFG_FOG
}
#declare Mat1 = material {
#if (QQ_MEDIA=0) texture { pigment { color <.6,.8,.97> filter .5 } finish { ambient
.5 } }
#else
texture { pigment { rgbf 1 } finish { ambient 0 diffuse 0 } }
interior {
media {
#local C =<.3,.4,.99>;
#local C2=<.3,.6,1.2>;
density { cylindrical
//color_map {[0 rgb .1*C][.2 rgb .15*C][0 rgb .3*C][.5 rgb .3*(C+C2)/2][.8
rgb .8*C2][1 rgb 1*C2]}
color_map {[0 rgb C*0][0.5 rgb C*0.25][1 rgb C2]}
}
emission .05
}
}
#end
}
#declare Mat2 = material {
#if (QQ_MEDIA=0) texture { pigment { color <.6,.8,.97> filter .5 } finish { ambient
.5 } }
#else
texture { pigment { rgbf 1 } finish { ambient 0 diffuse 0 } }
interior {
media {
#local C=<.3,.72,.99>;
density { cylindrical color_map {[0 rgb 0*C][.5 rgb .3*C][.8 rgb .7*C][1 rgb
1*C]} }
emission .6
}
}
#end
}
#local A1=-4; #local A2=+4; // <--- number of grid lines
#local E = 220; // <--- space between grid lines
#local R = 12; // <--- grid line thicknes
#local ofs = <12,1,2>; // <-- grid offset
#local J=A1; #while (J<A2) #local I=A1; #while (I<A2)
#declare obj =
cylinder {
y*-1000 y*+1000 1
material { Mat1 }
hollow
scale <R,1,R>
rotate z*90 translate <0,I,J>*E
}
object { obj translate ofs }
object { obj rotate y*90 translate ofs }
object { obj rotate z*90 translate ofs }
#local I=I+1; #end #local J=J+1; #end
#macro Cross(_a)
#local obj = merge {
cylinder { y*-50 y*-_a 1 }
sphere { 0 1 scale <1, 4, 1> translate -y*50 }
material { Mat2 } scale <9,1,9>
hollow
}
merge {
object { obj rotate z* 0 }
object { obj rotate z*180 }
object { obj rotate z*90 }
object { obj rotate z*270 }
object { obj rotate z*270 rotate y*90 }
object { obj rotate z*270 rotate y*270 }
}
#end
object { Cross(12) translate <-2,2,-3>/2+ofs }
#local objCross = Cross(3)
#local J=A1; #while (J<A2) #local I=A1; #while (I<A2) #local K=A1; #while (K<A2)
#if (I | J | K)
object { objCross scale 1/3 translate <I,J,K>*E + ofs }
#end
#local K=K+1; #end #local I=I+1; #end #local J=J+1; #end
Post a reply to this message
|
![](/i/fill.gif) |