in news:3be8c51f@news.povray.org Batronyx wrote:

> I can find no apparent way to get an interior_texture{} applied to
> a mesh in mesh2{} format.

No problem, see scene below. The material container isn't realy needed.

There is one minor "problem" though. The texture_list does not accept 
interior_texture. Nor does it accept materials, so it is not possible 
to use texture + interior_texture there.

---%<------%<---
#version 3.5;
global_settings {assumed_gamma 1.0}
light_source {<500,500,-500> rgb 1}
camera {location  <0.5, 0.5, 1.5> look_at<0.5, 0.5, 0>}
#declare T1= texture{pigment{wood scale 0.3}}
mesh2 {
   vertex_vectors {
      9, 
      <0,0,0>,<0.5,0,0>,<0.5,0.5,0>,
      <1,0,0>,<1,0.5,0>,<1,1,0>, 
      <0.5,1,0>,<0,1,0>,<0,0.5,0>   
   }

   uv_vectors {
      9
     <-0.5,-0.5>,<0,-0.5>,<0,0>,
     <0.5,-0.5>,<0.5,0>,<0.5,0.5>,
     <0,0.5>,<-0.5,0.5>,<-0.5,0>, 
   }
   
   texture_list {
      3,
      texture{pigment{wood scale 0.3}}
      texture{pigment{rgb 1}}
      texture{pigment{marble scale 0.2}}
   }
   
   face_indices {
      8, 
      <0,1,2>,0,1,2 <1,3,2>/*,0*/
      <3,4,2>,0,1,2 <4,5,2>/*,0*/
      <5,6,2>/*,0,1,2*/ <6,7,2>/*,0*/
      <7,8,2>/*,0,1,2*/ <8,0,2>/*,0*/
   }
   uv_indices {
      8, 
      <0,1,2>, <0,1,2>,
      <0,1,2>, <0,1,2>,
      <0,1,2>, <0,1,2>,
      <0,1,2>, <0,1,2>,
   }
   
   //uv_mapping

   material {
      texture{
         pigment{rgb <1,0,0>}
      }
      interior_texture{
         pigment{rgb 1}
      }
   }
}
---%<------%<---


Ingo

-- 
Photography: http://members.home.nl/ingoogni/
Pov-Ray    : http://members.home.nl/seed7/

Post a reply to this message