Pabs wrote:

>I don't really know how it is done or the math behind it but
>just my theories from what I have seen on TV.
>

A vertigo was the first thing I posted on this server, its gone by now. 
Here's the code for a simple version.

#version 3.1
#include "colors.inc"
global_settings {assumed_gamma 1}
light_source {<500,500,-500> rgb<1,1,1>}

#declare WOV=2;
#declare StartAngle= 10;
#declare StopAngle= 120;
#declare CamAngle= StartAngle+(clock*(StopAngle-StartAngle));
#declare Zcam= WOV/tan(radians(CamAngle/2));

camera {
    location  <0,1,-Zcam>
    look_at   <0,1,0>
    angle CamAngle
}

sky_sphere {
    pigment {
        gradient y
        color_map { [0 color blue 0.6] [1 color rgb 1]}
    }
}

plane { 
  y, 0
  texture {
    pigment {
        checker color rgb <1,1,1> color rgb <0,0,1> 
        scale 0.25
    }
    finish {reflection 0.2}
  }
}

#declare Count= -2;
#while (Count<=2)
    cylinder {
        <0,0,0>,<0,2,0>,0.02
        translate <Count,0,0>
        texture {
            pigment {color White}
            finish {diffuse 1}
        }    
    }
    #declare Count= Count+0.5;
#end


Ingo

-- 
Photography: http://members.home.nl/ingoogni/
Pov-Ray    : http://members.home.nl/seed7/

Post a reply to this message