Wasn't it Todd Haygood who wrote:
>Thanks everyone. Of course I see now that writing a single file with all of
>the camera vectors in a single file and having POV-Ray #read each frame is a
>much better way to do it. Can anyone point me to a simple working example of
>this type of I/O? I looked at the documentation, but I am still a little
>fuzzy.

#version 3.5;
global_settings {assumed_gamma 1.0}

#fopen FILE "camera.dat" read
#declare N=0;
#while (N<=frame_number)
  #read (FILE, Locn, LookAt, Angle)
  #declare N=N+1;
#end

camera {
  location   Locn
  look_at    LookAt
  angle      Angle
}

light_source {<-30, 100, -30> color rgb 1}
sphere {y,1 pigment { rgb 0 } finish {reflection 1}}
plane {y, 0
  pigment { checker rgb 1, rgb 0}
}


The "camera.dat" file looks like this. Note that the "," is required at
the ends of the lines if you have line breaks.

<0,0,-10>,<0,0.0,0>,50,
<2,1,-10>,<0,0.1,0>,45,
<4,2,-10>,<0,0.2,0>,40,
<6,3,-10>,<0,0.3,0>,35,
<7,4,-10>,<0,0.4,0>,30,
<6,5,-10>,<0,0.5,0>,35,
<4,6,-10>,<0,0.6,0>,40,
<2,7,-10>,<0,0.7,0>,45,
<0,8,-10>,<0,0.8,0>,50

-- 
Mike Williams
Gentleman of Leisure

Post a reply to this message