On 2026-05-08 21:45, Bald Eagle wrote:

> The "cubic_spline" type is a Catmull-Rom spline.
> So a cubic spline sphere sweep ought to be able to be overlaid on a sor rendered
> with an orthographic camera.
> 

I did that with my curve.inc from https://ingoogni.nl/download/ (curve.zip)

---%<------%<------%<---
//cmd: +w400 +h400 +am2 +a0.01

#version 3.7;

#include "curve.inc"

#global_settings{ assumed_gamma 1.0 }
#default{ finish{ ambient 0.1 diffuse 0.9 emission 0}}

sor {
   8,
   <0.0,  -0.5>,
   <3.0,   0.0>,
   <1.0,   0.2>,
   <0.5,   0.4>,
   <0.5,   4.0>,
   <1.0,   5.0>,
   <3.0,  10.0>,
   <4.0,  11.0>
   open
   pigment {rgb 1}
   sturm
}

#declare vC = array[8]{
   <0.0,  -0.5, 0.0>,
   <3.0,   0.0, 0.0>,
   <1.0,   0.2, 0.0>,
   <0.5,   0.4, 0.0>,
   <0.5,   4.0, 0.0>,
   <1.0,   5.0, 0.0>,
   <3.0,  10.0, 0.0>,
   <4.0,  11.0, 0.0>
};

#declare Test = CIcatmull(vC);
#for(T, 0, 1, 0.0015)
   sphere{CIget(Test, T), 0.05 pigment{rgb <1,0,0>} translate <0.1,0,0>}
#end

camera {
   orthographic angle 60
   location  <0, 5, -12>
   right     x*image_width/image_height
   look_at   <0, 5, 0.0>
}

light_source{<0, 10,-3000> color rgb 1}
---%<------%<------%<---

Note, the red line of the CatmullRom is slightly translated to the 
right. I does not match exactly. The CatmullRom is a case of Cardinal 
spline where one can set the tension. I have it implemented and a bunch 
of other types in Nim. I'll try to get them in POV-Ray and test against 
the SORspline.

ingo

Post a reply to this message

Attachments:
Download 'compare_sor.png' (37 KB)

Preview of image 'compare_sor.png'