On Thu, 15 May 2003 23:43:46 -0400, "Christina B."
<ccb### [at] tampabayrrcom> wrote:

>I really appreciate your explanation - too bad you didn't write the documentation!

I believe Warp did actually write part of the documentation :)

Anyway, I think you've got the concept of diffuse and ambient just a
tad off. I guess you've used some other 3D applications (probably
OpenGL ones) where you set the color of an object by its diffuse and
ambient _colors_. However, in POV you need to set a _pigment_ to the
object to determine the color of an object. The finish statement more
or less determines the luminance of that color depending on the light
position, incidence angle etc. (it's not so simple of course but at
least that's what diffuse, ambient and brilliance do).

Here's a more or less shiny object in a simple scene:

sphere {
	0,1
	texture {
		finish {
			ambient 0.1
			diffuse 0.9
			brilliance 1.75
			phong 0.4 phong_size 10
			specular 0.8 roughness 0.005
			reflection 0.125 metallic on
			conserve_energy
		}
		pigment { rgb <0.3,0.6,1> }
	}
}

light_source { <10,10,-10> color rgb 1 }

camera {
  location -4*z
  look_at 0
}

union {
  box { -1, 1 translate <-1.1,-1.1,0> }
  box { -1, 1 translate <-1.1,1.1,0> }
  box { -1, 1 translate <1.1,-1.1,0> }
  box { -1, 1 translate <1.1,1.1,0> }
  texture { pigment { rgb 1 } finish { ambient 1 } }
  scale <10,20,0.1>
  translate <30,20,-15>
  no_shadow
}

I hope this helps.


Peter Popov ICQ : 15002700
Personal e-mail : pet### [at] vipbg
TAG      e-mail : pet### [at] tagpovrayorg

Post a reply to this message