I get a segmentation fault with this scene:

----------[BEGIN CODE]---------
// +W300 +H240
#version 3.7;

global_settings
{ assumed_gamma 1
  max_trace_level 255
  photons { spacing 0.05 media 100 }
  radiosity
  { count 200
    error_bound 0.5
    pretrace_end 1 / image_width
    pretrace_start 16 / image_width
    recursion_limit 2
  }
}

camera
{ orthographic
  location -10 * z
  right 10 * x
  up 8 * y
}

light_source { <-0.6, 1, -2> * 1000, rgb 1 parallel point_at 0 }
background { rgb 0.25 }

#default { finish { ambient 0.125 diffuse 0.75 } }

#declare v_Scale = <3, 3, 2>;

difference
{ sphere { 0, 1 scale v_Scale }
  sphere { 0, 1 scale v_Scale - 0.5 }
  pigment { rgbf 1 }
  finish
  { reflection { 0, 1 fresnel } conserve_energy
    specular albedo 0.05 roughness 0.001
  }
  interior
  { ior 1.51673
    fade_color <0, 0.8, 0.4>
    fade_power 1001
    fade_distance v_Scale.z / 2
  }
  photons { target refraction on reflection on collect off }
}

plane
{ -z, -v_Scale.z - 0.001
  pigment { checker rgb 0.5 rgb 1 scale 2 translate x }
}
-----------[END CODE]----------

I used self-compiled POV-Ray 3.7.0.10 for Unix.  This code renders fine
with 3.8-beta 2, and the scene description file from which this code was
extracted rendered to completion with 3.7-RC7 back in 2013, so something
happened between 3.7-RC7 and 3.7.0.10 that did not carry over into 3.8.

The code renders fine if I delete both the photons *and* the radiosity,
but if I include either one, the scene seg faults.

Does anyone else get a seg fault with their POV-Ray 3.7?  Does anyone
see any mistakes I may have made in the code?

POV-Ray versions: POV-Ray 3.7.0.10 (self-compiled)
Operating system: openSUSE Leap 15.3 GNU/Linux
Hardware: Lenovo Ideapad Slim 7
CPU: Intel Core i7

Post a reply to this message