Right. This should be it I guess:

//-----------------------------------------------------------------
sphere {
   <0,0,0>, 1.00
   texture {
     pigment {srgb <0.8, 0.7, 0.7>*0.5 }
     finish {
       diffuse albedo 0.5  //note: should be 0.0 when metallic on
       specular albedo 0.4
       roughness 0.001
       brilliance 3, 3
       reflection {
         0.0, 0.4
         roughness 0.001
         fresnel on
         metallic off
       }
       fresnel on
       metallic off
       conserve_energy
     }
   }
   interior {ior 1.5}

   scale <1,1,1>  rotate <0,0,0>  translate <-1.35, 1.35, 0>
}

sphere {
   <0,0,0>, 1.00
   texture {
     pigment {srgb <0.8, 0.7, 0.7>*0.5 }
     finish {
       diffuse albedo 0.0  //note: should be 0.0 when metallic on
       specular albedo 0.4
       roughness 0.001
       //brilliance 3, 3
       reflection {
         0.0, 0.4
         roughness 0.001
         fresnel off
         metallic on
       }
       fresnel off
       metallic on
       conserve_energy
     }
   }
   interior {ior 1.5}

   scale <1,1,1>  rotate <0,0,0>  translate <1.35, 1.35, 0>
}
//-----------------------------------------------------------------

As I am still unsure about the looks_like object, in the case of a 
/sun-like/ object, this is the code I used although, to tell the truth, 
it could be left out in the present scene.

//-----------------------------------------------------------------
#declare SunPosition = <-3000, 3000, -3000>;
//apparent size of the Sun (courtesy Cousin Ricky)
#declare SunDis      = vlength(SunPosition)*2/215;

light_source {
     SunPosition
     color rgb <1, 1, 1>*10
     area_light
     SunDis*x, SunDis*z,
     5, 5
     adaptive 2
     jitter
     circular
     orient
     parallel
     point_at <0, 0, 0>
     looks_like {
       sphere {
         0, SunDis
         pigment {color rgb <1,1,1>*10000}
         //finish {emission 1}
         no_radiosity
         no_reflection
       }
     }
     //fade_power 2
     //fade_distance SunDis/2
     //area_illumination
}
//-----------------------------------------------------------------




-- 
Thomas

Post a reply to this message

Attachments:
Download 'rsocp_uber.png' (231 KB)

Preview of image 'rsocp_uber.png'