|
|
Hi(gh)!
On 01.07.2013 09:03, Thomas de Groot wrote:
> It seems to me that the triangle are floating, the vertices not being
> joint properly together.
I think they should, as this is the code for the mesh2:
#declare Earth_Slice=
mesh2
{
vertex_vectors
{
xdim*ydim
#declare row=0;
#while (row<ydim)
#declare col=0;
#while (col<xdim)
#declare clrvect=eval_pigment(map, <1/(xdim*2)+col/xdim,
1-(1/(ydim*2)+row/ydim), 1>);
// #warning concat("<",vstr(3, clrvect, ",",7,2),">")
// #warning concat(str(col,2,0)," ",str(row,2,0))
#declare hval=clrvect.red*65280+clrvect.green*255;
#declare hval=-deadsea+rng/65535*hval;
// #warning str(hval, 1, 2)
(rd+hval)*<sin(radians(-longstart-col/xdim))*cos(radians(latstart-row/ydim)),
sin(radians(latstart-row/ydim)),
cos(radians(-longstart-col/xdim))*cos(radians(latstart-row/ydim))>*sf
#if (!(row=ydim-1 & col=xdim-1)) // no comma after last vector
,
#end
#declare col=col+1;
#end
#declare row=row+1;
#end
}
face_indices
{
(xdim-1)*(ydim-1)*2
#declare r=0;
#while (r<ydim-1)
#declare c=0;
#while (c<xdim-1)
<r*xdim+c, r*xdim+c+1, (r+1)*xdim+c>,
<r*xdim+c+1, (r+1)*xdim+c+1, (r+1)*xdim+c>
#if (!(r=ydim-2 & c=xdim-2)) // no comma after last vector
,
#end
#declare c=c+1;
#end
#declare r=r+1;
#end
}
texture
{
pigment { color rgb <0, 0.8, 0> }
finish { ambient 0.1 diffuse 1 brilliance 0.4 }
}
double_illuminate
translate ApproxLook*sf
}
> If that is true, the solution is simple: load
> the mesh2 into Poseray, go to Groups, push the button labelled Weld
> vertices, save as mesh2 again.
Poseray? Is it free?
> Additionally, beware indeed of epsilon issues. Put the camera a little
> bit higher from the ground.
In my current scene, the camera is placed at "pedestrian eye's height",
i. e. 1.7 metres above ground. But the problem remains with any camera
height - the gaps then show up as black dots on the terrain!
See you in Khyberspace!
Yadgar
Now playing: Master of Sensation (Eloy)
Post a reply to this message
|
|