>Thomas de Groot  on date 26/03/2013 13.51 wrote:
> On 26-3-2013 11:02, Paolo Gibellini wrote:
>   I thought a simple texture based on the use of warp like the example
>> posted by Philippe some time ago (tex_Sol_en_galets).
>
> I am not sure I remember that one. Still, it is the texture of the
> complete height_field which shows through, so there would be need of a
> partial reworking.
>
> Thomas
>
>

Sorry, I don't remember the news, but the code posted by Philippe 
(2007-05-09) was very useful to me to understand the use of warp in 
textures.
It's a silly idea use a duplicate of the height_field clipped by the 
contour of the old city and translated a bit vertically?
Paolo


//Philippe's code
--------------------------------------------------------------------------------
#declare tex_Sol_en_galets_mortier=texture{
	pigment{color rgb <0.898039, 0.85098, 0.733333>}
	finish{diffuse .65}
	normal{granite .6 scale .4}
}

#declare tex_Sol_en_galets_galets=texture{
	pigment{color rgb <0.815686, 0.803922, 0.776471>*1.1}
	finish{
		diffuse .7
		specular .08 roughness .15
	}
	normal{
		average
		normal_map{
			[1.00
			spherical 7
			poly_wave .3
			slope_map{
				[0.00 <0,0>]
				[0.05 <0,0>]
				[0.05 <0,.5>]
				[1.00 <1,0>]
			}
			]
			[1.00 agate .15 ]
		}
	}
}

#declare tex_Sol_en_galets=texture{
	spherical
	poly_wave .3
	texture_map{
		[0.00 tex_Sol_en_galets_mortier]
		[0.05 tex_Sol_en_galets_mortier]
		[0.05 tex_Sol_en_galets_galets]
		[1.00 tex_Sol_en_galets_galets]
	}

	warp{planar}
	rotate -90*x
	scale .5
	translate <.5,0,.5>
	warp{repeat 1.1*x}
	warp{repeat z offset .5*x}
	#local tseg_Warp_scale=.3;
	scale tseg_Warp_scale
	warp{
		turbulence <.3,1.5,.3>
		octaves 4
		lambda 1.5
	}
	scale 1/tseg_Warp_scale
}

Post a reply to this message