On 14-4-2012 8:33, Norbert Kern wrote:
> look at the old LOTW2 project pages of Christoph Hormann
> (http://www.imagico.de/lotw2/history.php).
> Here you can find tons of nice procedural textures - but you have to extract the
> texture definitions from the files and includes...
>

Nice to play again with those landscapes. They stimulate ideas for 
future scenes.

I have "improved" the sky/Sun code for the LOTW scenes (see image 
below). The following code can be used for all of them I suppose, just 
copy and past the relevant section in the LOTW scene files. You need the 
CIE.inc file though, which can be found here: 
http://www.ignorancia.org/en/index.php?page=Lightsys

//start code
// --- part written by skies.inc ---

// ----------------------------------------
//  >>>> skysphere sky <<<<
// ----------------------------------------

#include "CIE.inc"
#declare SunColor = Blackbody(2800)*1;  //2800=red; 7500=white blue

#declare Azm = 20;
#declare Alt = 5;

#declare fn_horizon=function { max(z, 0) }

#declare fn_sun=
   function {
     pattern {
       spherical
       scale 3
       translate y
       rotate x*Alt
       rotate z*Azm
     }
   }

sky_sphere {
   pigment {
     function { pow(fn_horizon(x,y,z)*(1-fn_sun(x,y,z)), 0.400) }
     color_map {
       [0.000 color SunColor]
       [0.426 color rgb <0.200, 0.300, 0.800>]
     }
   }
}



// --- part written by lighting.inc ---

light_source {
  <0,0,0>
  color SunColor
  translate 10e5*y
  rotate x*Alt
  rotate z*Azm
}

sphere {
   0, 1
   hollow on
   no_shadow
   pigment { rgbt 1 }
   interior {
     media {
       emission SunColor/1000
       density {
         spherical
         poly_wave 4
         density_map {
           [0.0 rgb 0]
           [0.5 color rgb <0.3, 0.3, 0.3>]
           [1.0 color rgb <1, 1, 1>]
         }
       }
       samples 100 confidence .1
     }
   }
   scale 24000
   translate 10e5*y
   rotate x*Alt
   rotate z*Azm
}

//end code

Enjoy!

Thomas

Post a reply to this message

Attachments:
Download 'lotw 34_18_var.png' (483 KB)

Preview of image 'lotw 34_18_var.png'