Am 26.01.2012 21:52, schrieb Florian Siegmund:
> Excuse me for the missing explanation here, but I posted something in the bug
> reports group. Ior is 1.41 in both images (I'm not a complete fool though :) ),
> but the thing that disturbs me is that conserve_energy does not seem to work
> correctly in combination with fade_color. Is this a known issue or has nobody
> tried it before? Or is there probably a workaround or something else to achieve
> the desired effect?
>

Well, it would have been helpful to *see* your full material statement 
but anyway for dielectrics like glass something like this has always 
worked for me:


#macro Dielectric (COLOR, IOR, TRANSLUCENCY)
   material {
     texture {
       pigment {rgb COLOR filter 1}
       finish {
         ambient 0  diffuse 0
         reflection {0,1 fresnel on} conserve_energy
       }
     }
     interior {
       ior IOR
       fade_power 1001
       fade_distance TRANSLUCENCY
       fade_color rgb <pow(COLOR.red,3),
		      pow(COLOR.green,3),
		      pow(COLOR.blue,3)>
     }
   }
#end


note that this "fade_power 1001" statement is an old (and really dirty 
as it lacks any logic) hack that is part of POV-Ray since ages to turn 
realistic fade power calculation on.
The value for TRANSLUCENCY depends on your general scene scale and just 
to mention it: make sure your max_trace_level is high enough for all the 
internal bounces.

-Ive

Post a reply to this message