Hi all:
I finally found a simple way to create an endless stream of
wallpapers for my virtual rooms, using the new tiling pattern type 5
(thanks, clipka!), combined with repeat warps in a texture_map.
Here are a few samples attached. For these I used a William Morris
wallpaper design as input, but almost anything can be used (including
procedural textures, of course).
If you enjoy repetition, try the following code at your own risk... ;)
--
Jaime
// +w665 +h768
#version 3.7;
// change the seed until you find a nice result (shouldn't take more
than a few tries)
#declare r_pattern=seed(745);
// name of the PNG image to be used as a base
// the URL below doesn't works obviously, is just a recommended image source
#declare
imagemap="http://upload.wikimedia.org/wikipedia/commons/e/ed/Morris_Snakeshead_printed_textile_1876_v_2.jpg"
// and the desired scale for it...
#declare im_scale=5;
// create the random base texture
#declare t_base=
texture{
pigment{
image_map{jpeg imagemap interpolate 2}
rotate 90*x
translate rand(r_pattern)*x
translate rand(r_pattern)*z
rotate 360*rand(r_pattern)*y
scale im_scale
warp { repeat .5*x flip x}
warp { repeat sqrt(.75)*z flip z}
}
finish{emission 1}
}
// tiling
plane{z,1
texture{
pigment_pattern{tiling 5}
texture_map{
[0 t_base rotate -120*y]
[1/3 t_base rotate -120*y]
[1/3 t_base]
[2/3 t_base]
[2/3 t_base rotate 120*y]
[1.0 t_base rotate 120*y]
}
rotate -90*x
}
}
// render it seamless
camera{
orthographic
up 6/sqrt(.75)*y
right 6*x
}
Post a reply to this message
Attachments:
Download 'wpgen-t5-im_morris_snakeshead-01.jpg' (199 KB)
Download 'wpgen-t5-im_morris_snakeshead-02.jpg' (202 KB)
Download 'wpgen-t5-im_morris_snakeshead-03.jpg' (217 KB)
Download 'wpgen-t5-im_morris_snakeshead-04.jpg' (210 KB)
Preview of image 'wpgen-t5-im_morris_snakeshead-01.jpg'
![wpgen-t5-im_morris_snakeshead-01.jpg](/povray.binaries.images/attachment/%3C4f0376d8%40news.povray.org%3E/wpgen-t5-im_morris_snakeshead-01.jpg?preview=1)
Preview of image 'wpgen-t5-im_morris_snakeshead-02.jpg'
![wpgen-t5-im_morris_snakeshead-02.jpg](/povray.binaries.images/attachment/%3C4f0376d8%40news.povray.org%3E/wpgen-t5-im_morris_snakeshead-02.jpg?preview=1)
Preview of image 'wpgen-t5-im_morris_snakeshead-03.jpg'
![wpgen-t5-im_morris_snakeshead-03.jpg](/povray.binaries.images/attachment/%3C4f0376d8%40news.povray.org%3E/wpgen-t5-im_morris_snakeshead-03.jpg?preview=1)
Preview of image 'wpgen-t5-im_morris_snakeshead-04.jpg'
![wpgen-t5-im_morris_snakeshead-04.jpg](/povray.binaries.images/attachment/%3C4f0376d8%40news.povray.org%3E/wpgen-t5-im_morris_snakeshead-04.jpg?preview=1)
|