On 31/05/2011 7:15, RobF wrote:
> Hi Anthony,
>
> Since your planet is far away, you may also want to consider using the aoi
> pattern to fake an atmospheric glow. Although it doesn't give that soft/hazy
> look, it renders very fast.  Here's a code snippet and an example of what it
> looks like (with the USS Enterprise, of course! :-)

you could give it a soft/hazy look, even with some atmospheric 
discoloration near the terminator:

--- START CODE ---
#version 3.7;
global_settings {
   assumed_gamma 1
}

#local SunLocation=<500,300,200>*1000;
camera {
   location -z*3
   look_at 0
}
light_source {
   SunLocation
   rgb <1.5,1.4,1.3>
}

// the planet itself
sphere {0,1 pigment {crackle solid scale .1} finish {ambient 0}}

//the atmosphere
#local Atmosphere=<.4,.5,.9>;
sphere {
   0,1
   pigment {
     pigment_pattern {
       slope {point_at SunLocation}
       pigment_map {
         [.5 rgb 1]
         [1 rgb 0]
       }
     }
     poly_wave 2
     pigment_map {
       [.5
         pigment_pattern {
           pigment_pattern {aoi color_map {[0 rgb 1][.5 rgb 0][1 rgb 1]}}
           color_map {
             [0 rgb 0]
             [.15 rgb 1]
             [.5 rgb 0]
           }
         }
         color_map {
           [0 rgb Atmosphere transmit 1]
           [1 rgb .25+Atmosphere transmit .35]
         }
         poly_wave 2
       ]
       [1
         pigment_pattern {
           pigment_pattern {aoi color_map {[0 rgb 1][.5 rgb 0][1 rgb 1]}}
           color_map {
             [0 rgb 0]
             [.15 rgb 1]
             [.5 rgb 0]
           }
         }
         color_map {
           [0 rgb 1-Atmosphere transmit 1]
           [1 rgb .25+(1-Atmosphere) transmit .35]
         }
         poly_wave 2
       ]
     }
   }
   finish {diffuse 1 ambient 0}
   scale 1.02
}
--- END CODE ---

(It's the technique I used in my Babylon-video)

cu!
-- 
ZK

Post a reply to this message