> Got this many years ago as a CRT from...
> Man### [at] munichnetsurfde  (1998)  17 inch Syncmaster
> [Always credit the original :)]
> and made a flat screen....
> I wonder if anyone can help with the shadow on the screen :)
> //------------------monitor2.inc------------
> #declare flatscreen = version
> #version 1.0
>
>
>
> #declare Green_led = texture {
>    pigment { color rgbf<0.0, 0.9, 0.0, 6.0>  }
>    finish {
>      ambient 0
>      diffuse 0.1
>      reflection 0.1
>      refraction 1
>      ior 1.5
>      phong 0.1
>      phong_size 20
>    }
> }
>
>
> #declare computerBlack = texture {
>    pigment {color rgb<0.19647,0.19098,0.17529>}
>    normal { bumps 0.1 scale 0.1 }
>    finish { phong 0.5 }
> }
>
>
>
> //############################################################################
> // Monitor: HANNS-G HB191D
> // Creator : Colin B Maharaj
> //############################################################################
>
> #declare TYPICALFLATSCREEN =
> union
> {
>    union
>    {
>     cylinder{<0, 0,0>,<0,25,0>,145}  // Base plate
>      box{<-45,10,50>,<-25,125,-50>}  // Vertical suspension bar
>      box{<-65,80,100>,<-40,100,-100>}  // Front Panel Menu
>
>      difference
>      {
>        box{<-200, 95, -360>,<-230,420, 150>} // Monitor display area
>        box{<-235,105, -350>,<-220,410, 140>} // cut out area #1
>        box{<-235,100, -355>,<-229,415, 145>} // cut out area #2
>
>        translate<160,0,100>
>
>      }
>
>      texture{computerBlack}
>    }
>
>    union
>    {
>      box{<-70,90,-82>,<-40,80,-88>}  // Front panel LED...
>      texture{Green_led}             // ...coloured green
>    }
>
>
>
>    union
>    {
>
>      box {<-221,100,-355>,<-220,415,145>}
>      texture
>      {
>        pigment
>        {
>          image_map {bmp "desktop.bmp"} //1440x900
>          rotate<0,90,0>
>          scale<1,310,490>
>          translate<0,100,140>
>        }
>        ambient 0.3
>      }
>      translate<160,0,100>
>
>    }
> }
> //---end---------------monitor2.inc------------
>


Why do you use #version 1.0 ?

You would be much beter to use current syntax.
Remove that "refraction 1" and move the ior to it's proper place: the 
interior block.
filter 6 is prety strange...
in a pigment block, you don't need to use "color"

You can have this:
#declare Green_led = material{
	texture{ pigment{rgbf<0.5, 0.9, 0.5, 1>}
	finish{ambient 0 diffuse 0.1 reflection{0.1 0.5 fresnel}conserve_energy 
phong 0.1 phong_size 20}
	}
	interior{ior 1.5 fade_color <0.1, 1, 0.1> fade_distance 0.1 fade_power 
1001}
	}

Then, you can use emission 0.3 for the image on the screen.
It will continue to work if you use radiosity.


Alain

Post a reply to this message