|
|
I think we both mean the same thing :-)
As there is a lamp shade, I did not use a spotlight but simple point/area
lights within a scattering media. However, in both cases, the halo effect is
not really there like in the original, which is the reason for my emissive
media around the light source.
This is the media code I use for both halo and scattering:
//====start code
#local HaloScale = 100;
#local colLum = rgb <1.0, 1.0, 0.9>; // light color
#local haloTurb = 0.1; // outer halo turbulence
#local haloStrength = 0.5; // inner and outer halo intensity
(outer halo is 50% inner halo intensity)
#local DensityShift = 0.6; //0.9 // shifts the density within the media
#local DensityHalo =
density {
spherical
turbulence haloTurb
color_map {
[0.4 rgb 0]
[0.8 colLum*haloStrength*0.05]
[1.0 colLum*haloStrength*0.5]
}
scale <1, 1, 1>
translate DensityShift*y
}
#local mediaHalo =
media {
emission haloStrength*0.5
intervals 1
samples 100
confidence 0.9999
variance 1/10
density {DensityHalo}
}
#declare LampHalo =
sphere {0, 1
texture {pigment {rgb 0 transmit 1} finish {ambient 0 diffuse 0}}
interior {media {mediaHalo}}
hollow no_shadow
translate -DensityShift*y
scale HaloScale
translate <-0.09911, 1.861, 0.0> //locate halo center a bit within the
lamp shade
}
//__________________________________________________________________________________
// a scattering media around the street lamps
#if (Halo)
#declare LampHalo2 =
sphere {0, 1
texture {pigment {rgb 0 transmit 1} finish {ambient 0 diffuse 0}}
interior {
media {
intervals 1
samples 100
scattering {1, (colLum*0.1)/600} //200
density {
spherical
color_map {
[0.5 rgb 1]
[1.0 rgb 0]
}
}
}
}
hollow no_shadow
scale 600 //200
translate CamLoc
rotate CamRot*y
}
object {LampHalo2}
#end
//====end code
Thomas
Post a reply to this message
|
|