> I've used POV for a long time, but I find lighting to be one of my biggest
> challenges in scene development.  I thought it might be interesting to get some
> examples from the community on creative ways to light a scene:
>
> Below is a primitive scene (no pun intended) with only a basic light source.
> With the restriction that you aren't allowed to change the camera or the objects
> (including their mundane textures), what creative lighting solutions can you
> come up with to make this image more interesting?
>
>
>

   The most important thing is the light placement, as depending on it the 
shadows play will be interesting or boring. It's a difficult subject, 
because it depends on the composition, but I usually play with rand() to 
find interesting placements... after trying some seeds, you may get an idea 
of which placements make for interesting shots (for this scene, and in 
general too):


#version 3.6;
#include "colors.inc"

global_settings {
   assumed_gamma 1.0
   max_trace_level 10
   radiosity{count 160 error_bound 0.5 nearest_count 10}
}

#default{texture{finish{ambient 0 diffuse 1}}}

#declare r_l=seed(117);
light_source { <-10-10*rand(r_l), 10*rand(r_l), -10-10*rand(r_l)>
  color rgb White*150
  area_light 1*x,1*z,4,4 jitter adaptive 1 orient circular
  fade_distance 1
  fade_power 2
  rotate 360*rand(r_l)*y
}
light_source { <-10-10*rand(r_l), 10*rand(r_l), -10-10*rand(r_l)>
  color rgb Gold*100
  area_light 1*x,1*z,4,4 jitter adaptive 1 orient circular
  fade_distance 1
  fade_power 2
  rotate 360*rand(r_l)*y
}

// ----------------------------------------
// Basically, everything below here should
// remain the same
// ----------------------------------------

#include "glass.inc"

camera {
   location  <0, 5, -5>
   look_at   <0, 0,  0>
}

plane {
    y, -1
    texture {
       pigment {
          gradient x
          color_map {
             [0.0 rgb <0.6, 0.4, 0.4>]
             [0.5 rgb <0.2, 0.6, 0.8>]
             [1.0 rgb <0.6, 0.4, 0.4>]
          }
          scale 4
          rotate -45*y
       }
       normal {
          granite
          0.6
          scale 1.75
       }
    }
}

box {
    -1, 1
    scale <1,0.999,1>
    texture{
       pigment {
          gradient y
          color_map {
             [0.0 rgb <0.9, 0.1, 0>/8]
             [1.0 rgb <0.9, 0.1, 0>]
          }
          scale 2
          translate -y
       }
       finish {
          diffuse 0.6
          brilliance 1.0
          phong 0.5
          phong_size 40
          specular 0.5
          roughness 0.05
          metallic 1
          reflection {
             0.5
             1.0
             fresnel on
             falloff 1.0
             exponent 1.0
             metallic 0.9
          }
          conserve_energy
       }
       normal {
          granite 0.15
          scale 2
       }
    }
    rotate 25*y
    translate <-3.25,0,2>
}

sphere {
    0, 1
    texture {
       pigment {
          bozo
          color_map {
             [0.0 rgb <1,1,0>]
             [1.0 rgb <0,0,2>]
          }
          scale 0.2
       }
       finish {
          brilliance 0.4
          phong 0.25
          phong_size 70
          specular 0.65
          roughness 0.005
       }


    }
    translate <0,0,3>
}

torus {
    1.0,
    0.25
    texture {
       pigment {
          gradient x
          color_map {
             [0.0 rgb <1,0,1>/1]
             [0.3 rgb <1,0,1>/4]
             [0.6 rgb <1,0,1>/2]
             [1.0 rgb <1,0,1>/1]
          }
          scale 0.25
          warp {
             turbulence 0.25*x
          }
       }
       finish {
          diffuse 0.8
          brilliance 1.0
          phong 0.5
          phong_size 25
          specular 0.15
          conserve_energy
       }
    }
    translate <1.75,-0.75,-1.75>
}


cone {
    -y,2,
    2*y,0
    material {
       texture {
          pigment {
             color Col_Glass_Orange

          }
          finish {F_Glass3}
       }
       interior {I_Glass}
    }
    translate <4,0,3>
}

cylinder {
    <-2,-0.5,-2>, <0,-0.5,0>, 0.5
    texture {
       pigment {
          dents
          color_map {
             [0.0 rgb <1,1,0>/2]
             [0.5 rgb <1,1,0>]
             [1.0 rgb <1,1,0>/2]
          }
          scale 1/4
       }
       normal {
             crackle 1.5
             scale 1/4
       }
    }
    translate <-1,0,-1>/2
}

-- 
Jaime Vives Piqueres

http://www.ignorancia.org

Post a reply to this message