On 26.01.2010 23:14, Reuben Pearse wrote:
> Great rendering!

Thanks!

> I've only used the basic PoseRay settings for rendering so far but I
>  would love to create some more realistic renders. Any chance you
> could post some code or hints on lighting / radiosity settings?
>

I'm not using LDraw just an very old include file of mine where only the
very basic bricks (the ones I actually did have) are defined. Also the
scene is an old one and I just used higher quality settings for 
area_lights and focal_blur for this contemporary rendering as meanwhile 
I have something faster than a 200 MHz Pentium  ;)


The used finish for the bricks is:

#declare LegoFinish = finish {
     ambient 0  diffuse 0.775
     specular 0.6  roughness 0.012
     reflection  {0.01 0.125 falloff 2} conserve_energy
}


and for "glass" bricks

#declare LegoTransFinish = finish {
     ambient 0  diffuse 0.5
     specular 0.6  roughness 0.012
     reflection  {0 1 fresnel on}  conserve_energy
}


I have only defined the basic colors (again the ones I actually did 
have) and the values are taken from
http://www.peeron.com/cgi-bin/invcgis/colorguide.cgi
but are inverse gamma corrected to have them in linear color space as
they should be:

#macro GI(C)
   #local C = color C;
   <pow(C.red/255, 2.2),
    pow(C.green/255, 2.2),
    pow(C.blue/255, 2.2),
    C.filter>
#end


#declare LegoBlack  = GI(<  31,  45,  52, 0 >);//No.26 Black
#declare LegoWhite  = GI(< 240, 241, 240, 0 >);//No. 1 White
#declare LegoGrey   = GI(< 161, 165, 162, 0 >);//No. 2 Gray
#declare LegoRed    = GI(< 196,  40,  27, 0 >);//No.21 Bright Red
#declare LegoGreen  = GI(<  75, 151,  74, 0 >);//No.37 Bright Green
#declare LegoBlue   = GI(<  13, 105, 171, 0 >);//No.23 Bright Blue
#declare LegoYellow = GI(< 245, 205,  47, 0 >);//No.24 Bright Yellow
#declare LegoGlass  = GI(< 235, 240, 241, 0.885 >);


The lighting is just very basic (again it is an old scene) just 2 
area_light and a shadowless fill-light positioned exactly at the camera 
position.

And of course assumed_gamma has to be 1.0 for POV-Ray versions prior 3.7 
and has to be removed for the 3.7 beta versions.

I figured that there would be no interest for my "old-school" Lego 
include file where just the basic bricks and the old wheels are defined. 
If there is some interest I could prepare it for download and add the 
scene file for the shown image as usage example.
But as I would have to clean it up a bit and add a few comments it might 
take a few days, just tell me.

-Ive

Post a reply to this message