I have started to play with Ive's skin techniques and come up - for the time 
being - with the following ideas, illustrated by the attached image.

First of all, defining a skin color means that you need to define separate 
basic image_maps for the different skin features, e.g. one for the face 
skin, one for the lips, one for the eye sockets, one for the skull maybe, 
etc, depending on the details you want to show. This is not impossible to do 
using the basic image template but it is a delicate work.

That said, for most purposes, the skin image maps provided by Poser are of 
enough quality for direct use. What is often needed though is a better 
control of the apparent texture of the skin, the gloss, the transparancy. 
This last one could certainly be obtained by SSS but I do not want to go 
into that right now. I think that others are better qualified than me to 
give advice there.

The shininess or gloss of the skin can be improved however quite easily by 
applying a correct finish to the skin texture. You can do this in Poseray, 
by manipulating the finish box in the material section, fine-tuning later in 
POV-Ray itself. Alternatively, you can define your own finish code in 
Poseray or in POV-Ray. Ive's finish code with the SkinOil parameter is very 
interesting for that purpose and I have modified his texture code in order 
to be ablt to fully apply it to the standard skin textures of Poser.

The three images (Poser 8, Alyson figure; morphed to unique facial 
characteristics)  below, all with 16bps png image maps, have the following 
characteristics (only the heads have been modified):

1. Original figure with minimal finish improvements (specular 0.05 roughness 
0.005 for the gloss)

2. A skin material derived fro Ive's have been used, with SkinOil value 
0.01. The code for the texture here is:

//the different image maps:
#declare PP_Head = pigment{p_map4}
#declare S_Head  = pigment{p_map6}
#declare N_Head  = normal {p_map5}

#local N_Face =
normal {
   uv_mapping N_Head
   bump_size 1
}

#local F_Skin_S0 =
finish {
   ambient 0  diffuse 1
   specular 0.01 roughness 0.11
   phong 0.01  phong_size 2
   brilliance 1
}

#local F_Skin_S1 =
finish {
   ambient 0  diffuse 1 - 0.1 * SkinOil
   specular 0.01 + 0.75 * SkinOil roughness 0.06
   phong 0.01 + 0.5 * SkinOil  phong_size 5
   metallic 0.4 brilliance 1.05
}

#local T_Head_S0 =
texture {
   pigment {uv_mapping PP_Head}
   normal {N_Face}
   finish {F_Skin_S0}
}

#local T_Head_S1 =
texture {
   pigment {uv_mapping PP_Head}
   normal {N_Face}
   finish {F_Skin_S1}
}

#local M_Head =
material {
   texture {
     pigment_pattern {uv_mapping S_Head}
     texture_map{
       [0 T_Head_S0]
       [1 T_Head_S1]
     }
   }
}

3. Same as 2 but with SkinOil value 0.1.


The results show that Ive's finish is giving a more natural aspect to the 
face imo.

For the eye's cornea (the transparant outer layer), I use a material I 
developed myself:

#declare F_EyeTrans=
finish {
  specular 1
  roughness 0.001
  ambient 0
  diffuse 0
  reflection 0.05
}

#declare I_EyeTrans =
interior { ior 1.5 }

#declare T_EyeTrans =
texture {
  pigment { rgbf<1.0, 1.0, 1.0, 0.7> }
  finish  { F_EyeTrans }
}
#declare M_EyeTrans =
material {
  texture { T_EyeTrans }
  interior { I_EyeTrans }
}



Thomas

Post a reply to this message

Attachments:
Download 'PoserFiguretest_comb.jpg' (114 KB)

Preview of image 'PoserFiguretest_comb.jpg'