|
|
scott escreveu:
>> In any case, here's food for thought:
>> http://en.wikipedia.org/wiki/Dielectric_Shader
>
> Doesn't POV already support the Fresnel equations, Snell's law and
> Beer's law?
>
> One thing that seems better than POV is that it supports direct
> dielectric-dielectric interface, in POV you either have to go back
> through air, mess with coincident surfaces, or have two interfaces.
I've tried very hard to emulate one of those renders in the past:
http://i36.tinypic.com/i267wi.png
not quite like it. Perhaps I should use some more extreme settings and
render times? Colors are never that vivid and transparent!
here's the code:
/**
* mental ray can, so can povray
**/
#local GI = no;
#local CAUSTICS = on;
#local SOFTSHADOWS = on;
#local BLUR = 30;
background { rgb 0 }
#macro reflmat( fdcol )
/*texture {
pigment { rgbt fdcol + <0,0,0,.96> }
finish {
diffuse .0 ambient .0 brilliance 1.1 metallic 1
}
}*/
texture {
//pigment { rgbt <1,1,1,.97> }
pigment { rgbft fdcol + <0,0,0,.3,.68> }
finish {
diffuse 20 ambient .0 brilliance 3 metallic 1
reflection { .05,.98 metallic 0 fresnel on exponent 2 }
conserve_energy
}
}
hollow
interior { ior 1.5 //fade_power 2 fade_distance .2 fade_color
fdcol*1
//media { scattering { 1, fdcol/10 extinction 1 } }
media { absorption (1-fdcol)*.16 samples 5 }
media { emission .3*fdcol }
}
photons { target on refraction on collect off }
#end
// cena
union {
// chao
plane { y, 0 pigment { rgb 1 } finish { ambient .06 diffuse .6 }
photons { target off refraction on collect on }
}
// as duas semi-roscas: red (x) e blue (z)
union {
torus { 1.2,.16 reflmat( z ) rotate x*90 translate -y*.0 + x/3 }
torus { 2,.2 reflmat( x ) rotate x*90+y*90 translate -y*.4 }
translate -y/2
}
light_source { 7*y 1.5
#if (SOFTSHADOWS)
//spotlight point_at 0
area_light 1.4*x,1.4*z,5,5 jitter adaptive .001
#end
photons { refraction on area_light }
}
box { -1,1 scale y*2 translate y*5 no_image no_shadow pigment { rgb
1 } finish { ambient 2 diffuse 1 } }
rotate -y*30
rotate -x*30
translate z*6+y/5
}
camera { angle 30 #if (BLUR) focal_point 0 aperture .002 blur_samples
BLUR #end }
global_settings {
max_trace_level 60
#if (GI)
ambient_light .002
radiosity {
brightness 1.6
count 60
error_bound .5
gray_threshold .7
}
#end
#if (CAUSTICS)
photons { /*spacing .1*/ count 500000 }
#end
}
--
a game sig: http://tinyurl.com/d3rxz9
Post a reply to this message
|
|