some time away from pov, back to basics.  Rendered under ancient 3.6 and 
the old radiosity...


#include "colors.inc"

background { rgb 0 }

#default {finish {ambient 0 diffuse .6}}
global_settings {
	ambient_light 0
	radiosity { brightness 1.4 count 256*4 pretrace_end .006 error_bound .2 }
}

camera { location <-7, 4, -8> look_at 0
    angle 60
    focal_point y blur_samples 30*5 aperture .3 variance 0 confidence 1
}

// main light source and radiosity equivalent
light_source { 30*<1,1,-1> White/1 area_light 3*x,3*y,3,3 circular jitter }
box { -3/2,3/2 scale z/10 scale 7
	pigment { rgb 1 } finish { ambient 10 diffuse 1 }
	translate -z*70 rotate <45,-45> no_reflection
}

// backlight
light_source { 9*<-2,2,5> rgb <1,1,.7>*.8 shadowless }


plane { y 0 pigment { checker Black White } }

sphere { y 1 pigment { Red } }

cylinder { 0, 2*y 1 pigment { Yellow } translate 4*z rotate y*90*0 }
box { -1,1 translate y pigment { Magenta } translate 4*z rotate y*90*1 }
cone { 0, 1, 2*y, 0 pigment { Orange } translate 4*z rotate y*90*2 }
torus { 1,.5 translate y*.5/2 pigment { Green } translate 4*z rotate 
y*90*3 }

Post a reply to this message

Attachments:
Download 'semana1e2.png' (303 KB)

Preview of image 'semana1e2.png'