|
![](/i/fill.gif) |
you're using photon mapping for the caustics, right? Ever since these
guys have been posting these bruteforce renders, I've been noticing an
interesting pattern about photon mapping: the caustics don't match the
shape of the source of light, you look at your render and to that of
Severi and you notice your caustics are focused in one point while his
are large and in the shape of the light sphere. And that is to be
expected, since photon mapping reacts to the (point)light source, not to
a physical object emitting light, like in the bruteforce methods.
But radiosity works ok for that purpose. Like here, just first
radiosity pass as I don't have the time right now for a complete
render... there are a few radiosity artifacts left, you could raise the
count a bit...
#local GIgather = 1;
#default { pigment { rgb 1 } finish { ambient 0 diffuse .5 } }
global_settings {
adc_bailout .02
radiosity {
brightness 1.8
gray_threshold .3
error_bound .1
low_error_factor .5
#if (GIgather)
save_file "pde.rad"
count 80*4
recursion_limit 3
always_sample no
nearest_count 16
pretrace_end .006
#else
load_file "pde.rad"
count 1
recursion_limit 1
always_sample no
nearest_count 1
pretrace_end 1
pretrace_start 1
#end
}
}
#macro refl()
#if (!GIgather)
reflection 1
#end
#end
union {
plane { y, 0 }
plane { x, -2 }
// light ball
sphere { y*2-x/2, .8 pigment { rgb <1,.9,.6> } finish { ambient 3
diffuse 1 }}
// back balls
sphere { <-1,1,2>, 1 pigment { rgb x } finish { diffuse 1/3 refl()
metallic .5 }}
sphere { <1,1,2>, 1 pigment { rgb x+y } finish { diffuse 1/3 refl() }}
// glass ball
sphere { <.2,.5,-.6>, .4 pigment { rgbt 1 } finish { diffuse 0 } hollow
interior {ior 1.33}}
sphere { <-.7,.7,-1.5>, .4 pigment { rgbt 1 } finish { diffuse 0 }
hollow interior {ior 1.33}}
}
camera {
location <0,1.4,-5>
look_at 0
angle 55
#if (!GIgather)
aperture .01 blur_samples 40*6 variance .0000001 confidence .99
#end
}
Post a reply to this message
Attachments:
Download 'pretty_damn_easy.jpg' (16 KB)
Preview of image 'pretty_damn_easy.jpg'
![pretty_damn_easy.jpg](/povray.binaries.images/attachment/%3C47c2edb4%40news.povray.org%3E/pretty_damn_easy.jpg?preview=1)
|
![](/i/fill.gif) |