|
![](/i/fill.gif) |
"Jim Charter" <jrc### [at] msn com> schreef in bericht
news:47b5144d$1@news.povray.org...
>
> Looking better and better. I think it mostly needs more variation between
> stones and areas.
Thanks Jim. I am still not really happy with this although there is
improvement. Yes, variation is needed and easy to do (implemented now to
some extend; see below).
>
> Not sure what you mean by 'crackle solid' pattern. Are you using a none
> standard form? What this actually reminds me of is the 'cells' pattern
> which might be something worth trying too.
To simulate the lichen I used a color_map with crackle solid. Here is the
macro code (state of the art) I used for the tiles. You only need to define
a parameter T (here: 0.4), a seed value for the parameter RR, and include
rand.inc. Note that I lowered the diffuse value of the lichen to 0.5. A
quick render shows this to be much better. The lichen now blends better with
the surrounding stone.
//-- Start Code --
#macro StoneTex()
#declare PLichen =
pigment {
crackle solid
color_map {
[0.45 rgbf <1.0, 1.0, 1.0, 1.0> ]
[0.50 rgb <249, 224, 142>/255 ]
[0.55 rgb <163, 149, 26>/255 ]
[0.555 rgbf <1.0, 1.0, 1.0, 1.0> ]
[0.60 rgb <215, 172, 67>/255 ]
[0.65 rgb <124, 82, 0>/255 ]
[0.655 rgbf <1.0, 1.0, 1.0, 1.0> ]
[0.70 rgb <255, 217, 126>/255 ]
[0.75 rgb <155, 111, 50>/255 ]
[0.755 rgbf <1.0, 1.0, 1.0, 1.0> ]
[0.80 rgb <176, 155, 98>/255 ]
[0.85 rgb <126, 106, 53>/255 ]
[0.855 rgbf <1.0, 1.0, 1.0, 1.0> ]
[0.90 rgb <249, 224, 142>/255 ]
[0.95 rgb <163, 149, 26>/255 ]
}
scale <1.0, 1.0, 1.0>*0.02
warp {turbulence 0.1}
}
#local Amount = RRand(T-0.1, T+0.1, RR);
#declare TLichen =
texture {
pigment {
granite
pigment_map {
[Amount color rgbf <1.0, 1.0, 1.0, 1.0> ]
[Amount PLichen]
}
//scale <1.0, 1.0, 2.0>*0.1
//warp {turbulence <1.0, 1.0, 1.0>}
}
normal {
crackle 10.0 solid
bump_size 2.0
scale 0.01
//warp {turbulence <1.0, 1.0, 1.0>}
}
finish {
ambient 0.0
diffuse 0.5
}
}
#declare LichenLimestone =
material {
// Limestone:
texture {
pigment {
agate
agate_turb 1.0
pigment_map {
[0.0 color rgb <1.0, 1.0, 1.0>*0.3]
[0.4 color rgb <0.6, 0.6, 0.6>*0.3]
[0.8 color rgb <0.9, 0.9, 0.9>*0.3]
[1.0 color rgb <0.7, 0.7, 0.7>*0.3]
}
scale <3.0, 0.3, 1.0>*0.05
rotate <-10.0, 0.0, 15.0>
}
normal {
crackle 10 solid
warp {turbulence 0.5}
scale 0.2
}
finish {
ambient 0.0
brilliance 0.5
specular 0.3525
roughness 0.005
}
}
// Lichen:
texture {TLichen}
}
#end
//-- End Code --
>
> Now you've gotten me googling antique ruins. They really are powerful
> images.
Fascinating indeed. High potential for interesting scenes but also fairly
difficult to do correctly is my own feeling.
Thomas
Post a reply to this message
|
![](/i/fill.gif) |