This is for the TC-RTC.  The rock face is a series of procedural height 
fields, made from a few different patterns averaged together.

I didn't use a smooth height field because the border between any two 
hfs is rather obvious until the resolution is high enough to make 
smoothing unecessary.

The texture is this:

#local rsA=seed(0);

   texture {
     pigment { marble frequency 1 ramp_wave turbulence <.1,01,.1> omega 
.4 lambda 1.5
       pigment_map {
#local sA=.5;
         [0 bumps scale <.1,1,.1> translate 0-64
           color_map { [0 rgb <.7,.675,.65>+<.1,.05,0>*sA][1 rgb 
<.9,.875,.85>+<.1,.05,0>*sA] }
         ]
#local iI=1;#while(iI<128)
         [(iI-.01)/128 bumps scale <.1,1,.1> translate iI-64
           color_map { [0 rgb <.7,.675,.65>+<.1,.05,0>*sA][1 rgb 
<.9,.875,.85>+<.1,.05,0>*sA] }
         ]
         #local sA=rand(rsA);
         [(iI+.01)/128 bumps scale <.1,1,.1> translate iI+1-64
           color_map { [0 rgb <.7,.675,.65>+<.1,.05,0>*sA][1 rgb 
<.9,.875,.85>+<.1,.05,0>*sA] }
         ]
#local iI=iI+1;#end
         [1 bumps scale <.1,1,.1> translate 128-64
           color_map { [0 rgb <.7,.675,.65>+<.1,.05,0>*sA][1 rgb 
<.9,.875,.85>+<.1,.05,0>*sA] }
         ]
       }
     }
     normal { marble 1 frequency 1 ramp_wave turbulence <.1,.01,.1> 
omega .4 lambda 1.5
       normal_map {
#local iI=0;#while(iI<129)
         [iI/128 bumps .031 scale <.1,1,.1> translate iI-64 ]
#local iI=iI+1;#end
       }
     }
     transform FlipXY
     scale <1000,150,1000>
   }

There will be a tunnel entrance here when I'm done.

Regards,
John

Post a reply to this message

Attachments:
Download 'cliff.jpg' (86 KB)

Preview of image 'cliff.jpg'