William Tracy wrote:
> I *like* the flames on that!
> 
> How did you do them?

Thanks. Here's the code:

#version unofficial megapov 1.20;

camera{
  fisheye
  right x*.5*1.33 up y*.5
  location<0,0,-20>
  look_at<0,0,0>
  angle 52
}

#declare flame_color1= <1,.75,.5>;
#declare flame_color2= <1,1,.5>;
#declare flame_pigment_start= function{pattern{cylindrical }}
#declare flame_pigment=
pigment{
  function{
   flame_pigment_start(x*z/2,0,z*.5+pow(x*.75,2))
  }
  pigment_map{
   [0 rgbt 1]
   [1
    cylindrical scale 2*<1.5,1,1> translate -z*2 poly_wave 2.5
    color_map{[0 rgb flame_color2*1.5][1 rgb<1,1,3>]}
   ]
  }
  scale .25*<1,1,1.75>
  warp{turbulence .1 lambda 1}
}

// the visible flame
#macro flame_object(flame_offset)
  box{<-1,-2,0>,<1,2,0>
   pigment{flame_pigment rotate x*270 scale 2 translate z*flame_offset}
   finish{ambient 1 diffuse 0}
  }
#end

// change macro offset value for naturally different flames
object{flame_object(4)}

// a glow :)
glow{type 0 location y*.125 color flame_color1/8 size 1.25}

~Sam

Post a reply to this message