For the water, I decided to use the normal as a function for a height_field.
I'm pretty happy with it.

#declare w1 =
texture {
 //pigment {rgb <1, 1, 1> transmit 1}
 pigment {color rgbt <1, 1, 1, 1>}
 normal {
  average
  normal_map {
   [1.0 agate 0.25 scale <0.5, 0.1, 0.2>]
   [1.0 granite 0.25 scale <0.5, 0.1, 0.2>]
  }
 }
 finish {
  specular 1
  roughness 0.003
  diffuse 0.3
  reflection {
   0, 0.5
   fresnel on
  }
 }
}

#local wp1 =
pigment {
 average
 pigment_map {
  [1.0 agate scale <0.5, 0.1, 0.2>]
  [1.0 granite scale <0.5, 0.1, 0.2>]
 }
}

#declare fnWater = function {pigment {wp1}}

height_field {
  function 2000, 2000 { fnWater(x, y, z).grey * 0.85 }
  smooth
  translate <-0.5, -0.5, -0.5>
  scale <200, 1, 200>
  texture {w1}
  interior {
  ior 1.3
  media {
   absorption <0.25, 0.1, 5.0, 0.5>*1
   scattering { 2 <0.2, 0.6, 0.4> }
  }

  fade_distance 2
  fade_power 1001
 }
}

Post a reply to this message

Attachments:
Download 'lull.jpg' (77 KB)

Preview of image 'lull.jpg'