jhu wrote:
> That is rather weird. Why does it look like things are moving?!?

I don't really know the "why", but I deduced the "what" from Akiyoshi's
illusions, so I was able to reproduce the effect with POV-Ray. It has to
do with the use of complementary colors separated by black and white
zones. When disposed on certain repeating but changing structures, these
will cause the impression of motion in the direction of the
transformation. Here is a little example:

/*

     Color motion experiments after Akiyoshi's illusions:

     http://www.ritsumei.ac.jp/~akitaoka/index-e.html

     To obtain a different pattern, change the r_op seed

     Jaime Vives Piqueres 2006

*/
global_settings{max_trace_level 8}
#include "colors.inc"
#include "textures.inc"
#include "functions.inc"

// complementary colors
//#declare c1=rgb <.75,0,.25>;
//#declare c2=rgb <.25,.75,0>;
#declare c1=rgb <1,.5,0>;
#declare c2=rgb <0,.5,1>;

// repeating pattern
#declare r_op=seed(630);
#declare xd=1000*rand(r_op);
#declare yd=1000*rand(r_op);
#declare f_pig=function{
    pattern{
     gradient x
     rotate 360*rand(r_op)*z
     warp{repeat x flip x}
    }
}
#declare p1=
pigment{
     function{
      f_pig(x+xd,y+yd,0)
     }
     color_map{
      [0.0 rgb 1]
      [0.1 rgb 1]
      [0.1 c1]
      [0.5 c1]
      [0.5 rgb 0]
      [0.6 rgb 0]
      [0.6 c2]
      [1.0 c2]
     }
}
plane{z,2
    texture{
     pigment{p1}
     finish{Luminous}
     scale .125
    }
}

// kaleidoscope for the repeating
#declare kd=.2;
plane{y,0 texture{Mirror} translate -kd*y}
plane{y,0 texture{Mirror} translate -kd*y rotate 120*z}
plane{y,0 texture{Mirror} translate -kd*y rotate 240*z}

// square camera
camera{
    location <0,0,-1>
    direction 1*z
    up 1*y right 1*x
}

--
Jaime

Post a reply to this message

Attachments:
Download 'color-motion-5i.jpg' (219 KB)

Preview of image 'color-motion-5i.jpg'