"jhu" <nomail@nomail> schreef in bericht 
news:web.44da190e38d3f8508f9cd9930@news.povray.org...
> Great image so far. How did you texture the pillars? I've been trying to 
> get
> the same effect, but mine doesn't look quite right.
>

Thank you!
I struggled a long time before coming up with something useful. The basis is 
a simplebrick pattern, but I included it in a macro to be able to scale the 
elements according to needs. This is the code:

//---- start of code ----

#macro LimeBricks()
  #ifndef (BrickSize)  #declare BrickSize = <1.6, 0.6, 1.6>; #end
  #ifndef (MortarSize)  #declare MortarSize = 0.02; #end
  texture {
    brick
    texture {  // Mortar
      pigment {
        color rgb <0.90005, 0.89995, 0.89995>
      }
      normal {
        bozo , 0.5
        bump_size -2.0
        scale  0.1
      }
    }
    texture { // Limestones
      pigment {
        agate
        agate_turb 1.0
        pigment_map {
          [0.0   color rgb <0.95, 0.95, 0.95>]
          [0.4   color rgb <0.91, 0.91, 0.91>]
          [0.8   color rgb <0.94, 0.94, 0.94>]
          [1.0   color rgb <0.91, 0.91, 0.91>]
        }
        scale  <30.0, 30.0, 30.0>/10
        rotate    <-10.0, -15.0, 0.0>
      }
      normal {
        agate , 0.2
        agate_turb 1.0
        scale  <30.0, 30.0, 30.0>/10
        rotate    <-10.0, -15.0, 0.0>
      }
      finish {
        ambient 0.05
        diffuse 0.7
      }
      scale  0.05
      rotate 90.0 * x
    }
    // BrickAndMortar
    rotate -90.0 * x
    translate <10, 10, 0>
    brick_size BrickSize
    mortar MortarSize
    scale <1,1,-1>
    rotate <90,0,0>
  }
  #undef BrickSize
  #undef MortarSize
#end  //of LimeBricks macro

//this is the default texture used in the wall:
#declare TdG_LimestoneBricks = LimeBricks()

//this is the texture for the flagstones on the ground:
#declare BrickSize = <0.1, 1, 0.1>;
#declare MortarSize = 0.003;
#declare TdG_LimestoneFlagstones = LimeBricks()

//this is the texture for the columns:
#declare BrickSize = <100, 10, 100>;
#declare MortarSize = 0.075;
#declare TdG_LimestoneColumns = LimeBricks()

//---- end of code ----


Thomas

Post a reply to this message