Hello,

just a quick doodle (eventually it should become kind of a wallpaper, oh
my...)
The motion blur was done in a single POV run without post processing. Just
an animation loop, and the following code:

#if (clock_on)
 #if (frame_number!=final_frame)
  //
  // Scene stuff goes here....
  //

 #else
  // composite
  camera {
   orthographic
   location -z
   look_at 0
   right x*image_width
   up y*image_height
  }

  box {
   <-image_width,-image_height,0>/2,<image_width,image_height,1>/2
   pigment {
    average
    pigment_map {

     #local fn=initial_frame;
     #while (fn<=final_frame-1)
      #local _t=fn/(final_frame-1-initial_frame);

      [2-pow(((_t-0.5)*2),2)
       image_map {
        concat("mblur",str(fn,-1,0),".bmp") // Adjust "-1" to the number of
digits in the file names
        once
        interpolate 4
       }
       translate -0.5
       scale <image_width,image_height,1>
      ]

      #local fn=fn+1;
     #end

    }
   }
   finish { ambient 1 diffuse 0}
  }

 #end
#else
 #error "Animation loop must be enabled!"
#end


single image and averaged image below.

Micha

Post a reply to this message

Attachments:
Download 'mblur20.jpg' (28 KB) Download 'mblur40.jpg' (14 KB)

Preview of image 'mblur20.jpg'

Preview of image 'mblur40.jpg'