Cyrano wrote:
> Thank you for the suggestions regarding the Thai statue.
> 
> I did try a few of the textures from stones.inc including T_Stone12 (I like
> that texture and probably use it more often than I should.) The grain in
> those textures seemed to hide the details of the statue somehow.
> 
> Attached is an example of what one of my attempts at a granite texture did
> to the details. Yikes!
> 
> I'm starting to wonder if the statue should have a soft stone texture with a
> relatively small range of color... Are any such textures predefined?
> 
The example I posted was quite harsh but obviously you can make it softer

Either scale it up  to get he soft cloud-like look that granite can give 
or way down to give a very fine speckled look

What made my example so harsh was the choppy pigment map in the original 
function:

                         pigment_map {
                                 [ 0 rgb 0 ]
				[ .4 rgb 1 ]
				[ .6 rgb 0 ]
                                 [ 1 rgb 1   ]
                         }
which alternates shapely between black, "0",
and white, "1"

the use of turbulence,

and the heavy applicaton of the normal in the actual texture:

         normal {
                 function {
                         F_Granite(x,y,z).gray*.4
                 }
         }

the ".4" multiplier looks very rough for the small scaling
I used in the original function, ".2"

But all this is also relative to the scale of your model so there
is not always a predefined thing that will work without tweaking

The straight granite texture scaled to 1 or greater should usually give
a soft cloud-like look  Soften it further when you apply the colours. 
Remove the normal or use only a small multiplier.
try this:

         #declare F_Granite =
         function {
                 pigment {
                         granite
                         scale 5
                 turbulence 0
                 //this affects the pattern:
                         pigment_map {
                                 [ 0 rgb 0 ]
                                 [ 1 rgb 1   ]
                         }
                 }
         }

         #declare T_Statue=
         texture{

                 pigment {
                         function {
                                 F_Granite(x,y,z).gray
                         }
                 //this applies the actual colours:
                         pigment_map {
                                 [ 0 rgb .25  ]
                                 [ 1 rgb Tan ]
                         }
                 }
                 finish{ //tweak these
                         diffuse .8
                         specular .2
                         roughness .002
                         ambient 0
                         reflection{0}
                 }
                 normal {
                         function {
                                 F_Granite(x,y,z).gray*.04
                         }
                 }
         } ;

Post a reply to this message