try this dude...  Is it what your after

#include "colors.inc"


camera {
  location  <0.0, 25, -40.0>
  look_at   <0.0, 25,  0.0>
}

sky_sphere {
  pigment {
    gradient y
    color_map {
      [0.0 rgb <0.6,0.7,1.0>]
      [0.7 rgb <0.0,0.1,0.8>]
    }
  }
}

light_source {
  <0, 0, 0>            // light's position (translated below)
  color rgb <1, 1, 1>  // light's color
  translate <-30, 30, -30>
}

#declare bobblybits = union     {
        sphere  {
                <0,0,0>,
                .5
                translate <-2,0,0>
                texture { pigment { Red } finish { phong .5 } }
                }
        sphere  {
                <0,0,0>,
                .5
                translate <2,0,0>
                texture { pigment { Red } finish { phong .5 } }
                }
        cylinder{
                <-2,0,0>,
                <2,0,0>,
                .15
                texture { pigment { White } finish { phong .5 } }
                }
        };


#declare halfHelix = union      {

        #declare myCount = 0;

        #while(myCount < 100)
                object  {
                        bobblybits
                        translate <0,myCount/1.2,0>
                        rotate <0,myCount*4,0>
                        }
                #declare myCount = myCount + 1;
        #end
        };

object  {
        halfHelix
        }
object  {
        halfHelix
        rotate <0,90,0>
        }

Post a reply to this message