"fcueto" <fcu### [at] yahoocom> wrote in message
news:4028152d$1@news.povray.org...
>
> > istr eye structure similar to flies
> > hexagon based
> > can't remember the word! sad
>
> honeycomb structure?

Compound eyes.

Very cool dragonfly rendering!

Maybe the hexagon pattern would 'warp' (not wrap) spherically okay... Just
not sure though, not having done that myself-- until now:

global_settings{assumed_gamma 1}

// suburban clear sky colors
sky_sphere {
  pigment {
    gradient y
    color_map {
      [0.0 rgb <0.7,0.65,0.75>]
      [0.025 rgb <0.6,0.6,0.8>]
      [0.05 rgb <0.4,0.6,1.1>]
      [0.15 rgb <0.25,0.55,1.2>]
      [0.4 rgb <0.2,0.45,1.1>]
      [1.0 rgb <0.15,0.35,0.8>]
    }
  }
}

camera {
        location <1,2,-3>
        look_at 0
}

light_source {-100*z, 1 rotate <45,45,0>}

plane {y,-1
        pigment {checker color rgb 1, color rgb 0}
}

sphere {0,1
 pigment {hexagon color red 1, color green 1, color blue 1
  scale 0.005
  warp {spherical orientation <0,1,0> dist_exp 0}
  }
 normal {hexagon 0.25
  scale 0.005
  warp {spherical orientation <0,1,0> dist_exp 0}
 }
 finish {ambient 0 diffuse 0.8 specular 0.3
  reflection {<0.1,0.2,0.5>,<0.9,0.5,0.1> falloff 0.5 metallic}}
 scale <1.125,1,0.75>
}

So I guess it could look right done this way, except that I believe the
pattern might be nearly imperceptible even this close in reality. Ahh, and
now I find here http://www.ups.edu/biology/museum/dragoneye.html an example
of such an eye. This would require a crackle-like bordering for the
hexagons.

Bob H.

Post a reply to this message