"Dan P" <dan### [at] yahoocom> wrote in message
news:40214056@news.povray.org...
> "Felbrigg" <som### [at] microsoftcom> wrote in message
> news:40211dfa$1@news.povray.org...
> > I've already posted a couple of images in the binaries.images section
> namely
> > "Cactus halo" and "Rain Drops" but if you would like to help me out,
look
> > there for one I've just posted called "Spilled Liquid" (Source included)
> > This is an example of an almost but never quite right table top image.
If
> > you can give me some tips on how to improve it, adjusting the lighting
etc
> I
> > would be very grateful.
>
> No problem! I'll download those tonight when I get home (I'm at work right
> now). I look forward to seeing your efforts!!!

NICE JOB, Felbrigg!  JC had a good point about the background too. When we
have things that are reflective, we need something to reflect to make it
more intresting and make it stand out a bit. Another, different colored
light source in front and to the right gives it that extra something that
brings it alive (modified example follows):

#include "colors.inc"
#include "textures.inc"
#include "shapes.inc"


#declare SnakeWood =
texture {  /* Bottom wood-grain layer */
    pigment {
        wood
        turbulence 0.05
        color_map {
            [0.00 rgb <0.58, 0.45, 0.23>]
            [0.34 rgb <0.65, 0.45, 0.25>]
            [0.40 rgb <0.33, 0.23, 0.13>]
            [0.47 rgb <0.60, 0.40, 0.20>]
            [1.00 rgb <0.25, 0.15, 0.05>]
        }
    }
    finish {
        crand 0.02
        //ambient 0.32
        diffuse 0.63
        phong 0.2
        phong_size 10
    }
    normal { bumps 0.05 }
}
texture {     /* top layer, adds small dark spots */
    pigment {
        bozo
        color_map {
            [0.0 rgbt <1.00, 1.00, 1.00, 1.00>]
            [0.8 rgbt <1.00, 0.90, 0.80, 0.80>]
            [1.0 rgbt <0.30, 0.20, 0.10, 0.40>]
        }
    scale 0.25
    }
}


// New stuff -- DAP
light_source
{
  <60, 20, -50>
  color rgb <0.2, 0.25, 0.3>
  shadowless
}

sky_sphere
{
 pigment
 {
  wrinkles

  color_map
  {
   [0, rgb <0, 0, 0> ]
   [1, rgb <0.7, 0.6, 0.5> ]
  }

  scale <0.1, 0.1, 0.1>
 }
}






light_source {<-20, 20, 0> color White area_light  <5, 0, 0>, <0, 0, 5>, 11,
11 adaptive 1 jitter photons { refraction on reflection on } }

camera  {
        location <0,10,-25> look_at <0,0,0>
       }

//background { Black }//color <0.25,0.35,0.80> }
box     {
        <-1,-1,-1>,
        <1,1,1>
        texture {
                pigment { Red }
                }
        scale <2,2,2>
        rotate <0,-15,0>
        translate <2,1,10>
        }
box     {
        <-1,-1,-1>,
        <1,1,1>
        texture {
                pigment { Red }
                }
        scale <2,2,2>
        rotate <0,-16,0>
        translate <2,1,-9>
        }
cylinder{
        <-1,-1,-1>,
        <1,1,1>,
        1
        texture {
                pigment { White*2 }
                }
        scale <1,5,1>
        translate <-7,3,0>
        }

plane   { <0, 1, 0>, -0.001
        texture { SnakeWood }//pigment { checker pigment{Red},
pigment{White} } scale <10,10,10> rotate <0,43,0>}
        }

#declare Point1 = <-10,1,10>;
#declare Point2 = <-10,1,0>;
#declare Point3 = <-10,1,-10>;
#declare Point4 = <0,1,-10>;
#declare Point5 = <10,1,-10>;
#declare Point6 = <15,1,2>;     //<10,1,0>;
#declare Point7 = <10,1,2>;    //<10,1,10>;
#declare Point8 = <0,1,10>;
#declare Point9 = <-14,1,12>; //<-10,1,10>;
#declare Point10 = <-10,1,0>;
#declare Point11 = <-10,1,-10>;

merge {
// outside of the puddle
sphere_sweep {
        cubic_spline
        11,
        Point1,1
        Point2,1
        Point3,1
        Point4,1
        Point5,1
        Point6,1
        Point7,1
        Point8,1
        Point9,1
        Point10,1
        Point11,1
        }

// inside of the puddle
prism {
    cubic_spline
    0, // sweep the following shape from here ...
    2, // ... up through here
    11, // the number of points making up the shape ...
        <Point1.x,Point1.z>,
        <Point2.x,Point2.z>,
        <Point3.x,Point3.z>,
        <Point4.x,Point4.z>,
        <Point5.x,Point5.z>,
        <Point6.x,Point6.z>,
        <Point7.x,Point7.z>,
        <Point8.x,Point8.z>,
        <Point9.x,Point9.z>,
        <Point10.x,Point10.z>,
        <Point11.x,Point11.z>
  }

        hollow
        texture {
                pigment {
                        Clear // rgbt <0.858824,0.576471,0.439216>
                        }
                finish  {
                        reflection { 0.1,0.8 }
                        }
                }
        interior        {
                        ior Water_Ior
                        }
        translate <0,-1.5,0>

 }

Post a reply to this message