"incognito" <nomail@nomail> wrote in message
news:web.3fc5dad2b2b1540ca688d5670@news.povray.org...

>
> Hi again all,
>
> Now that I have partially created my light source in my radiosity trace by
> setting its ambient light level to 0.7 and setting the diffuse light value
> of all the other objects in the scene to be 0.5, I am confused I should
> make that light source object Luminous or Shiny? Really need the answer
> quick (if possible).
>
> Thank you very much.
>

I'm not sure what you mean by luminous or shiny in this context. 'Luminous'
would seem to equate to ambient value, but you've already stated that that is
set to 0.7. 'Shiny' presumably means the reflection value, but that is not
relevant in this case.

BTW could you just assure us that you've read the advanced tutorial on radiosity
scenes (4.1 in the docs). I just want to check you're doing what you actually
want, rather than misunderstanding something (radiosity works with scenes that
contain conventional light-sources as well as those lit entirely by 'glowing'
objects).

Here is a simple radiosity scene with no conventional lights:

#version 3.5;

#declare Radiosity=on;
#include "colors.inc"

global_settings {
  assumed_gamma 1.0
  #if (Radiosity)
    radiosity {
      pretrace_start 0.08
      pretrace_end   0.02
      count 35

      nearest_count 10
      error_bound 1
      recursion_limit 3

      low_error_factor 0.1
      gray_threshold 0.25
      minimum_reuse 0.02
      brightness 10

      always_sample off

      adc_bailout 0.01
    }
  #end
}

// ----------------------------------------

camera {
  location  <0,2,-4>
  look_at   <0,0,0>
}

// 'lightbulb'
sphere{
  0,0.5
  pigment{Yellow}
  finish{ambient 1}
  translate x*1
}

// 'lit object'
sphere{
  0.0.5
  pigment{White}
  finish{ambient 0}
  translate x*-1
}

box{ // also lit
  -10,10
  hollow
  pigment{White}
  finish{ambient 0}
}

Post a reply to this message