"pal### [at] yahoocom" <nomail@nomail> wrote in message
news:web.3fabb4055a367bd0d888c9910@news.povray.org...
> I try usse search function using words "object media interaction" but found
> no match
> So can somebody please answer to me: Can POV-Ray render interactive media
> sample from real life: smoke of cigaret is bend around finger
> if can just point me to reference povray maunal chapter
> Thanks alot!
> I found alternative program called Lightflow and he is capable of producing
> this effect but hard to work :(
>

The relevant part of the documentation is 6.8...

As to your specific request, this would be object media (as opposed to, say, a
fog that covered your whole scene).

Basically, you need to make a shape that matches your desired media shape, then
make it transparent and hollow, and fill it with media.

For smoke you will want to use scattering media (as opposed to emitting or
absorbing media - although adding some absorbing media into the mix can prevent
media fading away against light backgrounds).

I would suggest that blobs are the best shape for smoke.

Here's a short example:

#version 3.5;

#include "colors.inc"

camera {
  location  z*-8
  look_at   0
}

light_source {
  <0, 0, 0>
  color rgb <1, 1, 1>
  translate <-30, 30, -30>
}

#declare RadiusVal   = 1.0;
#declare StrengthVal = 1.0;
blob {
  threshold 0.6
  sphere { < 0.75,   0,    0>, RadiusVal, StrengthVal }
  sphere { <-0.375,  0.65, 0>, RadiusVal, StrengthVal }
  sphere { <-0.375, -0.65, 0>, RadiusVal, StrengthVal }
  scale 2
  pigment{rgbt 1}
  hollow
  interior{
    media{
      scattering{1, <0.2,0.2,0.4>}
      density{wrinkles scale 0.1}
    }
    media{
      absorption 1-<0.2,0.2,0.4>
      density{wrinkles scale 0.1}
    }
  }
}

plane{-z,-5 pigment{checker Black, White}}

Post a reply to this message