Shay wrote:

> If anyone else has a technique which might help, I would like to see
>your results as well. The point is to make a large height field from
>this small image map, so enlarging and smoothing the map is not allowed.

Just for fun, here are some images generated by using the source image as an
isosurface pigment function. The texture, lighting and camera are exactly
the same as your original full_resolution_hf image, so they are directly
comparable.

The "Interp4.jpg" image simply uses image_map interpolation 4.
(Interpolation 2 and no interpolation gives results which are almost
identical to smoothed and unsmoothed height_fields respectively).

#declare F=function{pigment{
  image_map { jpeg "hf_map.jpg" interpolate 4}
  }
}
#declare my_heightfield =
    isosurface {
        function { y-F(x,z,0).red }
        max_gradient 5.5
        contained_by{box{0,1}}
        open
}
object {
  my_heightfield
  pigment {rgb 1}
  translate <-.5, -.5, -.5>
  rotate y*135
}
background { rgb <1,1,1> }
camera { location <0.1,1,-1> look_at <0,0,-.08> }
light_source { <-40,180,2.5> color rgb 1 }

The "Interp2smooth.jpg" and "Interp4smooth.jpg" perform a smoothing
operation in the isosurface function as well as image_map interpolation 2
and 4 respectively. But that might be a bit of a cheat because it's
mathematically very similar to performing a Blur operation on the source
image before processing (except that the result has full floating point
precision instead of 256 bits)

Post a reply to this message

Attachments:
Download 'Interp2Smooth.jpg' (42 KB) Download 'Interp4.jpg' (64 KB) Download 'Interp4Smooth.jpg' (60 KB)

Preview of image 'Interp2Smooth.jpg'

Preview of image 'Interp4.jpg'

Preview of image 'Interp4Smooth.jpg'