The buildings to the right are grandstands full of people. I'll make that
more obvious if I get time to animate a few establishing shots.

I agree that the horizon's a bit dull. I'll re-work it after I finish some
of the other scenes (if I have time).

The source for the clouds and sky is just this:

sky_sphere {
 //sky gradient
 pigment {
  function { min(max(y,0),1) }
  scale 1.01
  translate -.01*y
  turbulence .02 lambda 3 omega .8
  poly_wave 1/8
  colour_map {
   [0 rgb <4,2,1> ]
   [1 rgb <1,2,3>/5 ]
  }
 }
 //lit bits of clouds
 pigment {
   spotted
   scale <1,.1,1>/2
   scale 30
   warp {
     turbulence .5
     octaves 2
     lambda 4
     omega .5
   }
   scale 1/30
   colour_map {
     [.65 rgb 1.5 transmit 1]
     [.75 rgb 1.5 transmit 0]
   }
 }
 //shadowed bits of clouds
 pigment {
   spotted
   scale <1,.1,1>/2
   scale 30
   warp {
     turbulence .5
     octaves 2
     lambda 4
     omega .5
   }
   scale 1/30
   translate -y*.01
   colour_map {
     [.65 rgb .6 transmit 1]
     [.75 rgb .6 transmit 0]
   }
 }
}

--
Tek
http://www.evilsuperbrain.com


"Peter Hertel" <peter@hertel**NOSPAM**.no> wrote in message
news:3e7c20b0@news.povray.org...
> > I know it's a small detail, but I really like the clouds in this. I
> added
> > them tonight as an afterthought. They're just a spotted pigment with
> an
> > interesting turbulence pattern, but they're one of the rare cases
> where the
> > effect looks exactly how it did in my head! The source for this
> pigment is
> > available if anyone wants it.
>
> The clouds look great, perhaps some of them are a bit long/wide, but
> it's not that important. I'd love to see the source for them btw!
> A bit more details on the buildings in the background would be nice..
> Perhaps make them a bit bigger? The building to the left looks great,
> what are the purpose of the buildings to the right?
> I'd like a bit more interesting horizon, perhaps some mountains, or if
> you're short on time just a simple ground fog to wash out the horizon
> line?
>
> Looking forward to the final animation, the ship movement and warp looks
> awesome!
>
> -Peter
>
>
>

Post a reply to this message