"Patrick Dugan" <pat### [at] usnetcomcorpcom> wrote in message
news:3e1de5ec@news.povray.org...
>
> I need someone with expertise in making "scattered textures."  I am trying
> to make skateboards wheels.
> I want the texture to be like milk.

It's all trial and error for me. I wasn't completely successful but I gave
your wheel media a try. I think the predominent thing needed was more
samples. Unless you use double digits or more there's going to be oddities
encountered, such as strange shadows and other inconsistencies. I added
density, as well as absorption, so those could be controlled instead of
leaving it up to a default. It's never easy to get the exact result you
want. So... here's what I ended up with:

camera {
  location  <0.0, 2.0, -5.0>
  look_at   <0.0, 0.0,  0.0>
  right     x*image_width/image_height
}

// create a regular point light source
light_source {
  0*x                  // light's position (translated below)
  color rgb <1,1,1>*0.8    // light's color
  translate <-5, 30, -10>
}
// Create an infinite sphere around scene and allow any pigment on it
sky_sphere {
  pigment {
    gradient y
    color_map { [0.0 color rgb <0.7,0.7,1.0>] [1.0 color blue 0.5] }
  }
}

#declare MediaTrans =
material{
   texture {
      pigment {
       rgbf 1
      }
      finish {
         ambient 0
         diffuse 1
         specular 0.75
         roughness 0.001
         reflection {
          0.025, 0.125 // it's shiney so why not reflect a little?
          }
      }
   }
   interior {
      ior 1.42 // was like water before... I just gave this a try instead
      media {
         method 3
         //intervals 10 // not really needed for type 3 media
         samples 75, 150 much more here, could be less perhaps
        // confidence 0.9
        // variance 1.0/128
        // ratio 0.9
         scattering {4, // type 4 seems to work well for solid things, imho
                             rgb 2.5 // being 80 might have caused trouble
(?)
                             extinction 0.75 // if this is low media seems
to lose solidness
          }
         density {
          rgb 25 // increase solidness (?)
         }
         absorption 0.25
      }
   }
}

#declare Metal =
material {
 texture {
  pigment {
   rgb 0.5
  }
  finish {
   ambient 0.5 // wanted it visible while checking media
   diffuse 0.5
   reflection {
    0.25, 0.5
   }
  }
 }
}

union {
torus {
 1, 0.5
 material {
  MediaTrans
 }
hollow
}
torus {
 0.3, 0.3
 material {
  Metal
 }
}
 rotate <90,45,0>
}

Post a reply to this message